字节码层面剖析程序执行过程

前言

利用jclasslib插件查看源代码生成的字节码，剖析程序代码在虚拟机内部的运行方式。

案例剖析

public class MethodAreaDemo {
    public static void main(String[] args) {
        int x = 500;
        int y = 100;
        int a = x / y;
        int b = 50;
        System.out.println(a + b);
    }
}

编译后字节码：

 0 sipush 500  //把500入栈操作数栈
 3 istore_1    //出栈保存到局部变量表槽1
 4 bipush 100  //把100入栈操作数栈
 6 istore_2    //出栈保存到局部变量表槽2
 7 iload_1     //读取局部变量表槽1入栈到操作数栈
 8 iload_2     //读取局部变量表槽2入栈到操作数栈
 9 idiv        //出栈两个型，相除结果入栈
10 istore_3    //出栈保存到局部变量表槽3
11 bipush 50   //把50入栈操作数栈
13 istore 4    //出栈保存到局部变量表槽4
15 getstatic #2 <java/lang/System.out : Ljava/io/PrintStream;>  //类或接口的值字段获取并推到操作数堆栈。获取#2
18 iload_3     //读取局部变量表槽3入栈到操作数栈
19 iload 4     //读取局部变量表槽4入栈到操作数栈
21 iadd        //出栈两个，相加结果入栈
22 invokevirtual #3 <java/io/PrintStream.println : (I)V>   //调用静态方法，新的栈帧，操作数栈出栈为新栈帧的入参参数
25 return     //栈帧结果返回

main方法开始执行，args入参保存在局部变量表槽0 2.0 sipush 500 :把500入栈操作数栈
3 istore_1 ：出栈500保存到局部变量表槽1
4 bipush 100 ：把100入栈操作数栈
6 istore_2 ：出栈100保存到局部变量表槽2 6. 7 iload_1 ：读取局部变量表槽1（500）入栈到操作数栈
8 iload_2 ：读取局部变量表槽2（100）入栈到操作数栈 8.9 idiv ：出栈两个（100,500），相除结果（5）入栈
10 istore_3 ：出栈保存到局部变量表槽3
11 bipush 50 ：把50入栈操作数栈 11.13 istore 4 ：出栈50保存到局部变量表槽4
15 getstatic #2 <java/lang/System.out : Ljava/io/PrintStream;> ：类或接口的值字段获取并推到操作数堆栈。获取#2符号引用对应的静态变量
18 iload_3 ：读取局部变量表槽3（5）入栈到操作数栈
19 iload 4 ：读取局部变量表槽4（50）入栈到操作数栈
21 iadd ：出栈两个（50,5），相加结果入栈(55)
22 invokevirtual #3 <java/io/PrintStream.println : (I)V> ：调用静态方法，新的栈帧，操作数栈出栈为新栈帧的入参参数,当前序号保存到程序计数器，新栈帧的方法返回地址也保存了当前程序运行的序号，当新栈帧运行结束（打印），返回当前位置。 17.25 return :栈帧结束返回

++i,i++和i=i++区别

public class test01 {
    public static void main(String[] args) {
        int i = 1;
        i = i++;
        int j = i++;
        int k = i + ++i * i++;
        System.out.println(i);
        System.out.println(j);
        System.out.println(k);
    }
}

输出结果：

4
1
11

编译的字节码指令

 0 iconst_1  //把常量1入栈到操作数栈
 1 istore_1  //出栈（1）保存到局部变量表槽1
 2 iload_1   //读取局部变量表槽1(1)入栈到操作数栈
 3 iinc 1 by 1 //将局部变量表中的槽1的变量按常量1增加(此时局部变量表槽1的数为2)。第一个位置1代表索引，第二个1表示常量。
 6 istore_1  //出栈（1）保存到局部变量表槽1（2变为1）
 7 iload_1   //读取局部变量表槽1(1)入栈到操作数栈
 8 iinc 1 by 1 //将局部变量表中的槽1的变量按常量1增加(此时局部变量表槽1的数为2)。
11 istore_2   //出栈（1）保存到局部变量表槽2
12 iload_1   //读取局部变量表槽1(2)入栈到操作数栈
13 iinc 1 by 1   //将局部变量表中的槽1的变量按常量1增加(此时局部变量表槽1的数为3)。
16 iload_1  //读取局部变量表槽1(3)入栈到操作数栈
17 iload_1  //读取局部变量表槽1(3)入栈到操作数栈
18 iinc 1 by 1 //将局部变量表中的槽1的变量按常量1增加(此时局部变量表槽1的数为4)。
21 imul  //操作数栈出栈两个数（3,3），相乘结果(9)入栈
22 iadd  //操作数栈出栈两个数（9,2），相加结果(11)入栈
23 istore_3 //出栈（11）保存到局部变量表槽3（11）
24 getstatic #2 <java/lang/System.out : Ljava/io/PrintStream;> //获取相关类
27 iload_1 //读取局部变量表槽1(4)入栈到操作数栈
28 invokevirtual #3 <java/io/PrintStream.println : (I)V>  //调用方法
31 getstatic #2 <java/lang/System.out : Ljava/io/PrintStream;> //获取相关类
34 iload_2 //读取局部变量表槽2(1)入栈到操作数栈
35 invokevirtual #3 <java/io/PrintStream.println : (I)V> //调用方法打印
38 getstatic #2 <java/lang/System.out : Ljava/io/PrintStream;> //获取相关类
41 iload_3  //读取局部变量表槽3(11)入栈到操作数栈
42 invokevirtual #3 <java/io/PrintStream.println : (I)V>  //调用方法打印
45 return //栈帧结束返回