PBR IBL BRDF LUT

纳铭
2,278 阅读4分钟

GGX重要性采样 - 闪之剑圣 - 博客园 (cnblogs.com) 重要性采样小结 - 知乎 (zhihu.com)

反射方程

image.png

镜面反射部分

image.png

简化 分割求和近似法

image.png image.png image.png

image.png 环境BRDF

image.png

  • 公式里的n就是示意图里面的cosTheta
  • 因为h,n和l,v的夹角相差不大,所以默认用cosTheta
  • 三维纹理已经有组合爆炸的存储量了,一般只用二维纹理
  • 代入F菲涅尔方程 简化方程
  • image.png
  • image.png
  • image.png
  • image.png
  • image.png
  • image.png
  • 由于 f(p,ωi,ωo) 已经包含 F 项，它们被约分了，这里的 f 中不计算 F 项。
  • 与特定材质的F无关,与金属与非金属无关,只与粗糙度有关和角度有关了
  • image.png
  • image.png
  • 只与两个参数有关的话,就可以用lut了
  • image.png

image.png 环境BRDF

float lod             = getMipLevelFromRoughness(roughness);
vec3 prefilteredColor = textureCubeLod(PrefilteredEnvMap, refVec, lod); //roughnesss
vec2 envBRDF          = texture2D(BRDFIntegrationMap, vec2(NdotV, roughness)).rg; //brdf
vec3 indirectSpecular = prefilteredColor * (F * envBRDF.x + envBRDF.y)  //fr
  • image.png
  • 直接通过glsl生成图片
vec2 IntegrateBRDF(float NdotV, float roughness)
{
    vec3 V;
    V.x = sqrt(1.0 - NdotV*NdotV);
    V.y = 0.0;
    V.z = NdotV;

    float A = 0.0;
    float B = 0.0;

    vec3 N = vec3(0.0, 0.0, 1.0);

    const uint SAMPLE_COUNT = 1024u;
    for(uint i = 0u; i < SAMPLE_COUNT; ++i)
    {
        vec2 Xi = Hammersley(i, SAMPLE_COUNT);
        vec3 H  = ImportanceSampleGGX(Xi, N, roughness);
        vec3 L  = normalize(2.0 * dot(V, H) * H - V);

        float NdotL = max(L.z, 0.0);
        float NdotH = max(H.z, 0.0);
        float VdotH = max(dot(V, H), 0.0);

        if(NdotL > 0.0)
        {
            float G = GeometrySmith(N, V, L, roughness);
            //(DF/(4*NdotL*NdotV))/DPF
            float G_Vis = (G * VdotH) / (NdotH * NdotV); //DG/pdf的感觉
            float Fc = pow(1.0 - VdotH, 5.0);//是公式里的

            A += (1.0 - Fc) * G_Vis;
            B += Fc * G_Vis;
        }
    }
    A /= float(SAMPLE_COUNT);
    B /= float(SAMPLE_COUNT);
    return vec2(A, B);
}
// ----------------------------------------------------------------------------
void main() 
{
    vec2 integratedBRDF = IntegrateBRDF(TexCoords.x, TexCoords.y);
    FragColor = integratedBRDF;
}

pdf

  • pdf 代表概率密度函数 (probability density function)，它的含义是特定样本在整个样本集上发生的概率。 image.png
float pdf = D * dotNH / (4.0 * dotVH);

由图和公式可得

  • X轴是法线与视角的角度dot,Y轴是粗糙度
  • 其取决于仰角θ，粗糙度α和菲涅耳项F。
  • 通常使用Schlick近似来近似F，其仅在单个值F0上参数化，从而使Rspec成为三个参数（仰角θ（NdotV），粗糙度α、F0）的函数。
  • 绿色是G>R,红色是R>G
  • 角度越大,dot越小,越靠近0
  • 2D查找纹理存储是菲涅耳响应的系数（R 通道）和偏差值（G 通道） 
    vec3 indirectSpecular = prefilteredColor * (F * envBRDF.x + envBRDF.y)  //fr

已知概念

  • 镜面反射项的半球方向反射率（hemispherical-directional reflectance），可以理解为环境BRDF（Environment BRDF）。
  • brdf积分贴图是查找表来的
  • brdf积分贴图默认是不变的
  • envBRDF.xy 在webgl1可能会出现精度不够的问题(osg.js里面有解决方案)
  • brdf积分贴图有两种计算方式:一种是默认的计算方法;UE4用的是trike方法;

BRDF计算

image.png

float G_SchlicksmithGGX(float dotNL, float dotNV, float roughness)
{
	float r = (roughness + 1.0);
	float k = (r*r) / 8.0;
	float GL = dotNL / (dotNL * (1.0 - k) + k);
	float GV = dotNV / (dotNV * (1.0 - k) + k);
	return GL * GV;
}

vec2 BRDF(float NoV, float roughness)
{
	// 在进行2D查找时，法线总是沿着z轴
	const vec3 N = vec3(0.0, 0.0, 1.0);
	vec3 V = vec3(sqrt(1.0 - NoV*NoV), 0.0, NoV);

	vec2 LUT = vec2(0.0);
	for(uint i = 0u; i < NUM_SAMPLES; i++) {
		vec2 Xi = hammersley2d(i, NUM_SAMPLES);
		vec3 H = importanceSample_GGX(Xi, roughness, N);
		vec3 L = 2.0 * dot(V, H) * H - V;

		float dotNL = max(dot(N, L), 0.0);
		float dotNV = max(dot(N, V), 0.0);
		float dotVH = max(dot(V, H), 0.0); 
		float dotNH = max(dot(H, N), 0.0);

		if (dotNL > 0.0) {
			float G = G_SchlicksmithGGX(dotNL, dotNV, roughness);
			float G_Vis = (G * dotVH) / (dotNH * dotNV);
			float Fc = pow(1.0 - dotVH, 5.0);
			LUT += vec2((1.0 - Fc) * G_Vis, Fc * G_Vis);
		}
	}
	return LUT / float(NUM_SAMPLES);
}

void main() 
{
	outColor = vec4(BRDF(inUV.s, 1.0-inUV.t), 0.0, 1.0);
}

#version 450

layout (location = 0) in vec3 inWorldPos;
layout (location = 1) in vec3 inNormal;
layout (location = 2) in vec2 inUV;

layout (binding = 0) uniform UBO {
	mat4 projection;
	mat4 model;
	mat4 view;
	vec3 camPos;
} ubo;

layout (binding = 1) uniform UBOParams {
	vec4 lights[4];
	float exposure;
	float gamma;
} uboParams;

layout(push_constant) uniform PushConsts {
	layout(offset = 12) float roughness;
	layout(offset = 16) float metallic;
	layout(offset = 20) float specular;
	layout(offset = 24) float r;
	layout(offset = 28) float g;
	layout(offset = 32) float b;
} material;

layout (binding = 2) uniform samplerCube samplerIrradiance;
layout (binding = 3) uniform sampler2D samplerBRDFLUT;
layout (binding = 4) uniform samplerCube prefilteredMap;

layout (location = 0) out vec4 outColor;

#define PI 3.1415926535897932384626433832795
#define ALBEDO vec3(material.r, material.g, material.b)

float D_GGX(float dotNH, float roughness)
{
	float alpha = roughness * roughness;
	float alpha2 = alpha * alpha;
	float denom = dotNH * dotNH * (alpha2 - 1.0) + 1.0;
	return (alpha2)/(PI * denom*denom); 
}

float G_SchlicksmithGGX(float dotNL, float dotNV, float roughness)
{
	float r = (roughness + 1.0);
	float k = (r*r) / 8.0;
	float GL = dotNL / (dotNL * (1.0 - k) + k);
	float GV = dotNV / (dotNV * (1.0 - k) + k);
	return GL * GV;
}

vec3 F_SchlickR(float cosTheta, vec3 F0, float roughness)
{
	return F0 + (max(vec3(1.0 - roughness), F0) - F0) * pow(1.0 - cosTheta, 5.0);
}

//预滤波线性采样
vec3 prefilteredReflection(vec3 R, float roughness)
{
	const float MAX_REFLECTION_LOD = 9.0; 
	float lod = roughness * MAX_REFLECTION_LOD;
	float lodf = floor(lod);
	float lodc = ceil(lod);
	vec3 a = textureLod(prefilteredMap, R, lodf).rgb;
	vec3 b = textureLod(prefilteredMap, R, lodc).rgb;
	return mix(a, b, lod - lodf);
}

//光源BRDF
vec3 specularContribution(vec3 L, vec3 V, vec3 N, vec3 F0, float metallic, float roughness)
{
	vec3 H = normalize (V + L);
	float dotNH = clamp(dot(N, H), 0.0, 1.0);
	float dotNV = clamp(dot(N, V), 0.0, 1.0);
	float dotNL = clamp(dot(N, L), 0.0, 1.0);

	vec3 lightColor = vec3(1.0);
	vec3 color = vec3(0.0);

	if (dotNL > 0.0) {
		float D = D_GGX(dotNH, roughness); 
		float G = G_SchlicksmithGGX(dotNL, dotNV, roughness);
		vec3 F = F_Schlick(dotNV, F0);		
		vec3 spec = D * F * G / (4.0 * dotNL * dotNV + 0.001);		
		vec3 kD = (vec3(1.0) - F) * (1.0 - metallic);			
		color += (kD * ALBEDO / PI + spec) * dotNL;
	}

	return color;
}

void main()
{		
	vec3 N = normalize(inNormal);
	vec3 V = normalize(ubo.camPos - inWorldPos);
	vec3 R = reflect(-V, N); 

	float metallic = material.metallic;
	float roughness = material.roughness;

	vec3 F0 = vec3(0.04); 
	F0 = mix(F0, ALBEDO, metallic);
	//光源
	vec3 Lo = vec3(0.0);
 	for(int i = 0; i < uboParams.lights[i].length(); i++) {
 		vec3 L = normalize(uboParams.lights[i].xyz - inWorldPos);
 		Lo += specularContribution(L, V, N, F0, metallic, roughness);
 	}   
	
	vec2 brdf = texture(samplerBRDFLUT, vec2(max(dot(N, V), 0.0), roughness)).rg;
	vec3 reflection = prefilteredReflection(R, roughness).rgb;	
	vec3 irradiance = texture(samplerIrradiance, N).rgb;

	// 漫反射辐照度(上)
	vec3 diffuse = irradiance * ALBEDO;	

	vec3 F = F_SchlickR(max(dot(N, V), 0.0), F0, roughness);

	// 镜面反射(下)
	vec3 specular = reflection * (F * brdf.x + brdf.y);

	// 环境的一部分
	vec3 kD = 1.0 - F;
	kD *= 1.0 - metallic;	  
	vec3 ambient = (kD * diffuse + specular);
	
	vec3 color = ambient + Lo;

	// 色调映射
	color = vec3(1.0) - exp(-color * uboParams.exposure);	
	// 伽马校正
	color = pow(color, vec3(1.0f / uboParams.gamma));

	outColor = vec4(color, 1.0);
}
avatar
文章
阅读
粉丝