🔮 SAP 发布 REST 接口「实例」前言 SE24 创建服务处理类，作为 IF_HTTP_EXTENSION 接

持续创作，加速成长！这是我参与「掘金日新计划 · 10 月更文挑战」的第8天，点击查看活动详情

前言

SE24 创建服务处理类，作为 IF_HTTP_EXTENSION 接口实现类
实现 IF_HTTP_EXTENSION~HANDLE_REQUEST 方法 - 进行数据处理
SICF 发布服务
Web 请求测试服务
SRT_LOG 查看错误日志

SE24 创建 Class

TCode SE24 创建服务处理类

选择 Class，Next

填入描述信息，Save 保存

实现接口 IF_HTTP_EXTENSION

实现方法

切换到 Methods 页签，双击 IF_HTTP_EXTENSION~HANDLE_REQUEST 方法进入源码页面

业务逻辑：获取 JSON 格式数据，并以 JSON 格式返回给外部系统
实现方法，激活

实现逻辑源码如下：

  METHOD if_http_extension~handle_request.

    DATA: lr_json_ser TYPE REF TO cl_trex_json_serializer,
          lr_json_des TYPE REF TO cl_trex_json_deserializer.
    DATA: lv_json_string TYPE string.
    DATA: gt_t005u TYPE TABLE OF t005u.
    DATA: lv_request TYPE string.
    DATA: BEGIN OF ls_request,
            spras TYPE spras,
            land1 TYPE land1,
          END OF ls_request.
    DATA lt_request LIKE STANDARD TABLE OF ls_request." 该内表格式要和外部传入参数格式一致

*&--- 获取调用时候传入的参数
    CLEAR: lt_request.
    lv_json_string = server->request->get_cdata( ). " 获取传入的 JSON 格式数据
    /ui2/cl_json=>deserialize(    " 把 JSON 格式的转化为 ABAP 内表, 把 LV_JSON_STRING 放入 LT_REQUEST 里面
                      EXPORTING
                        json = lv_json_string
                        pretty_name = /ui2/cl_json=>pretty_mode-camel_case
                      CHANGING
                        data = ls_request ).

    APPEND ls_request TO lt_request.

*&--- 设置返回数据格式
    CALL METHOD server->response->if_http_entity~set_content_type
      EXPORTING
        content_type = 'application/json'.

*&--- 获取要返回的数据
    IF lt_request[] IS NOT INITIAL.
      CLEAR: gt_t005u.

      SELECT *
        INTO TABLE gt_t005u
        FROM t005u
        UP TO 5 ROWS
        FOR ALL ENTRIES IN lt_request
        WHERE spras = lt_request-spras
          AND land1 = lt_request-land1.
    ENDIF.

*&--- 要返回的数据转换成 JSON 格式
    CLEAR: lv_json_string.

    CREATE OBJECT lr_json_ser
      EXPORTING
        data = gt_t005u[].
    CALL METHOD lr_json_ser->serialize.
    CALL METHOD lr_json_ser->get_data
      RECEIVING
        rval = lv_json_string.

*&--- 设置返回数据
    server->response->set_cdata(
            EXPORTING
              data   = lv_json_string    " Character data
          ).

  ENDMETHOD.