File: sed.info, Node: Top, Next: Introduction, Up: (dir)

GNU 'sed'

This file documents version 4.8 of GNU 'sed', a stream editor.

 Permission is granted to copy, distribute and/or modify this
 document under the terms of the GNU Free Documentation License,
 Version 1.3 or any later version published by the Free Software
 Foundation; with no Invariant Sections, no Front-Cover Texts, and
 no Back-Cover Texts.  A copy of the license is included in the
 section entitled "GNU Free Documentation License".

Menu:
Introduction:: Introduction
Invoking sed:: Invocation
sed scripts:: 'sed' scripts
sed addresses:: Addresses: selecting lines
sed regular expressions:: Regular expressions: selecting text
advanced sed:: Advanced 'sed': cycles and buffers
Examples:: Some sample scripts
Limitations:: Limitations and (non-)limitations of GNU 'sed'
Other Resources:: Other resources for learning about 'sed'
Reporting Bugs:: Reporting bugs
GNU Free Documentation License:: Copying and sharing this manual
Concept Index:: A menu with all the topics in this manual.
Command and Option Index:: A menu with all 'sed' commands and command-line options.

File: sed.info, Node: Introduction, Next: Invoking sed, Prev: Top, Up: Top

1 Introduction

'sed' is a stream editor. A stream editor is used to perform basic text transformations on an input stream (a file or input from a pipeline). While in some ways similar to an editor which permits scripted edits (such as 'ed'), 'sed' works by making only one pass over the input(s), and is consequently more efficient. But it is 'sed''s ability to filter text in a pipeline which particularly distinguishes it from other types of editors.

File: sed.info, Node: Invoking sed, Next: sed scripts, Prev: Introduction, Up: Top

2 Running sed

This chapter covers how to run 'sed'. Details of 'sed' scripts and individual 'sed' commands are discussed in the next chapter.

Menu:
Overview::
Command-Line Options::
Exit status::

File: sed.info, Node: Overview, Next: Command-Line Options, Up: Invoking sed

2.1 Overview

Normally 'sed' is invoked like this:

 sed SCRIPT INPUTFILE...

For example, to replace all occurrences of 'hello' to 'world' in the file 'input.txt':

 sed 's/hello/world/' input.txt > output.txt

If you do not specify INPUTFILE, or if INPUTFILE is '-', 'sed' filters the contents of the standard input. The following commands are equivalent:

 sed 's/hello/world/' input.txt > output.txt
 sed 's/hello/world/' < input.txt > output.txt
 cat input.txt | sed 's/hello/world/' - > output.txt

'sed' writes output to standard output. Use '-i' to edit files in-place instead of printing to standard output. See also the 'W' and 's///w' commands for writing output to other files. The following command modifies 'file.txt' and does not produce any output:

 sed -i 's/hello/world/' file.txt

By default 'sed' prints all processed input (except input that has been modified/deleted by commands such as 'd'). Use '-n' to suppress output, and the 'p' command to print specific lines. The following command prints only line 45 of the input file:

 sed -n '45p' file.txt

'sed' treats multiple input files as one long stream. The following example prints the first line of the first file ('one.txt') and the last line of the last file ('three.txt'). Use '-s' to reverse this behavior.

 sed -n  '1p ; $p' one.txt two.txt three.txt

Without '-e' or '-f' options, 'sed' uses the first non-option parameter as the SCRIPT, and the following non-option parameters as input files. If '-e' or '-f' options are used to specify a SCRIPT, all non-option parameters are taken as input files. Options '-e' and '-f' can be combined, and can appear multiple times (in which case the final effective SCRIPT will be concatenation of all the individual SCRIPTs).

The following examples are equivalent:

 sed 's/hello/world/' input.txt > output.txt

 sed -e 's/hello/world/' input.txt > output.txt
 sed --expression='s/hello/world/' input.txt > output.txt

 echo 's/hello/world/' > myscript.sed
 sed -f myscript.sed input.txt > output.txt
 sed --file=myscript.sed input.txt > output.txt

File: sed.info, Node: Command-Line Options, Next: Exit status, Prev: Overview, Up: Invoking sed

2.2 Command-Line Options

The full format for invoking 'sed' is:

 sed OPTIONS... [SCRIPT] [INPUTFILE...]

'sed' may be invoked with the following command-line options:

'--version' Print out the version of 'sed' that is being run and a copyright notice, then exit.

'--help' Print a usage message briefly summarizing these command-line options and the bug-reporting address, then exit.

'-n' '--quiet' '--silent' By default, 'sed' prints out the pattern space at the end of each cycle through the script (*note How 'sed' works: Execution Cycle.). These options disable this automatic printing, and 'sed' only produces output when explicitly told to via the 'p' command.

'--debug' Print the input sed program in canonical form, and annotate program execution. $ echo 1 | sed '%1%s21232' 3

      $ echo 1 | sed --debug '\%1%s21232'
      SED PROGRAM:
        /1/ s/1/3/
      INPUT:   'STDIN' line 1
      PATTERN: 1
      COMMAND: /1/ s/1/3/
      PATTERN: 3
      END-OF-CYCLE:
      3

'-e SCRIPT' '--expression=SCRIPT' Add the commands in SCRIPT to the set of commands to be run while processing the input.

'-f SCRIPT-FILE' '--file=SCRIPT-FILE' Add the commands contained in the file SCRIPT-FILE to the set of commands to be run while processing the input.

'-i[SUFFIX]' '--in-place[=SUFFIX]' This option specifies that files are to be edited in-place. GNU 'sed' does this by creating a temporary file and sending output to this file rather than to the standard output.(1).

 This option implies '-s'.

 When the end of the file is reached, the temporary file is renamed
 to the output file's original name.  The extension, if supplied, is
 used to modify the name of the old file before renaming the
 temporary file, thereby making a backup copy(2)).

 This rule is followed: if the extension doesn't contain a '*', then
 it is appended to the end of the current filename as a suffix; if
 the extension does contain one or more '*' characters, then _each_
 asterisk is replaced with the current filename.  This allows you to
 add a prefix to the backup file, instead of (or in addition to) a
 suffix, or even to place backup copies of the original files into
 another directory (provided the directory already exists).

 If no extension is supplied, the original file is overwritten
 without making a backup.

 Because '-i' takes an optional argument, it should not be followed
 by other short options:
 'sed -Ei '...' FILE'
      Same as '-E -i' with no backup suffix - 'FILE' will be edited
      in-place without creating a backup.

 'sed -iE '...' FILE'
      This is equivalent to '--in-place=E', creating 'FILEE' as
      backup of 'FILE'

 Be cautious of using '-n' with '-i': the former disables automatic
 printing of lines and the latter changes the file in-place without
 a backup.  Used carelessly (and without an explicit 'p' command),
 the output file will be empty:
      # WRONG USAGE: 'FILE' will be truncated.
      sed -ni 's/foo/bar/' FILE

'-l N' '--line-length=N' Specify the default line-wrap length for the 'l' command. A length of 0 (zero) means to never wrap long lines. If not specified, it is taken to be 70.

'--posix' GNU 'sed' includes several extensions to POSIX sed. In order to simplify writing portable scripts, this option disables all the extensions that this manual documents, including additional commands. Most of the extensions accept 'sed' programs that are outside the syntax mandated by POSIX, but some of them (such as the behavior of the 'N' command described in *note Reporting Bugs::) actually violate the standard. If you want to disable only the latter kind of extension, you can set the 'POSIXLY_CORRECT' variable to a non-empty value.

'-b' '--binary' This option is available on every platform, but is only effective where the operating system makes a distinction between text files and binary files. When such a distinction is made--as is the case for MS-DOS, Windows, Cygwin--text files are composed of lines separated by a carriage return and a line feed character, and 'sed' does not see the ending CR. When this option is specified, 'sed' will open input files in binary mode, thus not requesting this special processing and considering lines to end at a line feed.

'--follow-symlinks' This option is available only on platforms that support symbolic links and has an effect only if option '-i' is specified. In this case, if the file that is specified on the command line is a symbolic link, 'sed' will follow the link and edit the ultimate destination of the link. The default behavior is to break the symbolic link, so that the link destination will not be modified.

'-E' '-r' '--regexp-extended' Use extended regular expressions rather than basic regular expressions. Extended regexps are those that 'egrep' accepts; they can be clearer because they usually have fewer backslashes. Historically this was a GNU extension, but the '-E' extension has since been added to the POSIX standard (austingroupbugs.net/view.php?id…), so use '-E' for portability. GNU sed has accepted '-E' as an undocumented option for years, and *BSD seds have accepted '-E' for years as well, but scripts that use '-E' might not port to other older systems. *Note Extended regular expressions: ERE syntax.

'-s' '--separate' By default, 'sed' will consider the files specified on the command line as a single continuous long stream. This GNU 'sed' extension allows the user to consider them as separate files: range addresses (such as '/abc/,/def/') are not allowed to span several files, line numbers are relative to the start of each file, '$' refers to the last line of each file, and files invoked from the 'R' commands are rewound at the start of each file.

'--sandbox' In sandbox mode, 'e/w/r' commands are rejected - programs containing them will be aborted without being run. Sandbox mode ensures 'sed' operates only on the input files designated on the command line, and cannot run external programs.

'-u' '--unbuffered' Buffer both input and output as minimally as practical. (This is particularly useful if the input is coming from the likes of 'tail -f', and you wish to see the transformed output as soon as possible.)

'-z' '--null-data' '--zero-terminated' Treat the input as a set of lines, each terminated by a zero byte (the ASCII 'NUL' character) instead of a newline. This option can be used with commands like 'sort -z' and 'find -print0' to process arbitrary file names.

If no '-e', '-f', '--expression', or '--file' options are given on the command-line, then the first non-option argument on the command line is taken to be the SCRIPT to be executed.

If any command-line parameters remain after processing the above, these parameters are interpreted as the names of input files to be processed. A file name of '-' refers to the standard input stream. The standard input will be processed if no file names are specified.

---------- Footnotes ----------

(1) This applies to commands such as '=', 'a', 'c', 'i', 'l', 'p'. You can still write to the standard output by using the 'w' or 'W' commands together with the '/dev/stdout' special file

(2) Note that GNU 'sed' creates the backup file whether or not any output is actually changed.

File: sed.info, Node: Exit status, Prev: Command-Line Options, Up: Invoking sed

2.3 Exit status

An exit status of zero indicates success, and a nonzero value indicates failure. GNU 'sed' returns the following exit status error values:

0 Successful completion.

1 Invalid command, invalid syntax, invalid regular expression or a GNU 'sed' extension command used with '--posix'.

2 One or more of the input file specified on the command line could not be opened (e.g. if a file is not found, or read permission is denied). Processing continued with other files.

4 An I/O error, or a serious processing error during runtime, GNU 'sed' aborted immediately.

Additionally, the commands 'q' and 'Q' can be used to terminate 'sed' with a custom exit code value (this is a GNU 'sed' extension):

 $ echo | sed 'Q42' ; echo $?
 42

File: sed.info, Node: sed scripts, Next: sed addresses, Prev: Invoking sed, Up: Top

3 'sed' scripts

Menu:
sed script overview:: 'sed' script overview
sed commands list:: 'sed' commands summary
The "s" Command:: 'sed''s Swiss Army Knife
Common Commands:: Often used commands
Other Commands:: Less frequently used commands
Programming Commands:: Commands for 'sed' gurus
Extended Commands:: Commands specific of GNU 'sed'
Multiple commands syntax:: Extension for easier scripting

File: sed.info, Node: sed script overview, Next: sed commands list, Up: sed scripts

3.1 'sed' script overview

A 'sed' program consists of one or more 'sed' commands, passed in by one or more of the '-e', '-f', '--expression', and '--file' options, or the first non-option argument if zero of these options are used. This document will refer to "the" 'sed' script; this is understood to mean the in-order concatenation of all of the SCRIPTs and SCRIPT-FILEs passed in. *Note Overview::.

'sed' commands follow this syntax:

 [addr]X[options]

X is a single-letter 'sed' command. '[addr]' is an optional line address. If '[addr]' is specified, the command X will be executed only on the matched lines. '[addr]' can be a single line number, a regular expression, or a range of lines (*note sed addresses::). Additional '[options]' are used for some 'sed' commands.

The following example deletes lines 30 to 35 in the input. '30,35' is an address range. 'd' is the delete command:

 sed '30,35d' input.txt > output.txt

The following example prints all input until a line starting with the word 'foo' is found. If such line is found, 'sed' will terminate with exit status 42. If such line was not found (and no other error occurred), 'sed' will exit with status 0. '/^foo/' is a regular-expression address. 'q' is the quit command. '42' is the command option.

 sed '/^foo/q42' input.txt > output.txt

Commands within a SCRIPT or SCRIPT-FILE can be separated by semicolons (';') or newlines (ASCII 10). Multiple scripts can be specified with '-e' or '-f' options.

The following examples are all equivalent. They perform two 'sed' operations: deleting any lines matching the regular expression '/^foo/', and replacing all occurrences of the string 'hello' with 'world':

 sed '/^foo/d ; s/hello/world/' input.txt > output.txt

 sed -e '/^foo/d' -e 's/hello/world/' input.txt > output.txt

 echo '/^foo/d' > script.sed
 echo 's/hello/world/' >> script.sed
 sed -f script.sed input.txt > output.txt

 echo 's/hello/world/' > script2.sed
 sed -e '/^foo/d' -f script2.sed input.txt > output.txt

Commands 'a', 'c', 'i', due to their syntax, cannot be followed by semicolons working as command separators and thus should be terminated with newlines or be placed at the end of a SCRIPT or SCRIPT-FILE. Commands can also be preceded with optional non-significant whitespace characters. *Note Multiple commands syntax::.

File: sed.info, Node: sed commands list, Next: The "s" Command, Prev: sed script overview, Up: sed scripts

3.2 'sed' commands summary

The following commands are supported in GNU 'sed'. Some are standard POSIX commands, while other are GNU extensions. Details and examples for each command are in the following sections. (Mnemonics) are shown in parentheses.

'a' 'TEXT' Append TEXT after a line.

'a TEXT' Append TEXT after a line (alternative syntax).

'b LABEL' Branch unconditionally to LABEL. The LABEL may be omitted, in which case the next cycle is started.

'c' 'TEXT' Replace (change) lines with TEXT.

'c TEXT' Replace (change) lines with TEXT (alternative syntax).

'd' Delete the pattern space; immediately start next cycle.

'D' If pattern space contains newlines, delete text in the pattern space up to the first newline, and restart cycle with the resultant pattern space, without reading a new line of input.

 If pattern space contains no newline, start a normal new cycle as
 if the 'd' command was issued.

'e' Executes the command that is found in pattern space and replaces the pattern space with the output; a trailing newline is suppressed.

'e COMMAND' Executes COMMAND and sends its output to the output stream. The command can run across multiple lines, all but the last ending with a back-slash.

'F' (filename) Print the file name of the current input file (with a trailing newline).

'g' Replace the contents of the pattern space with the contents of the hold space.

'G' Append a newline to the contents of the pattern space, and then append the contents of the hold space to that of the pattern space.

'h' (hold) Replace the contents of the hold space with the contents of the pattern space.

'H' Append a newline to the contents of the hold space, and then append the contents of the pattern space to that of the hold space.

'i' 'TEXT' insert TEXT before a line.

'i TEXT' insert TEXT before a line (alternative syntax).

'l' Print the pattern space in an unambiguous form.

'n' (next) If auto-print is not disabled, print the pattern space, then, regardless, replace the pattern space with the next line of input. If there is no more input then 'sed' exits without processing any more commands.

'N' Add a newline to the pattern space, then append the next line of input to the pattern space. If there is no more input then 'sed' exits without processing any more commands.

'p' Print the pattern space.

'P' Print the pattern space, up to the first .

'q[EXIT-CODE]' (quit) Exit 'sed' without processing any more commands or input.

'Q[EXIT-CODE]' (quit) This command is the same as 'q', but will not print the contents of pattern space. Like 'q', it provides the ability to return an exit code to the caller.

'r filename' Reads file FILENAME.

'R filename' Queue a line of FILENAME to be read and inserted into the output stream at the end of the current cycle, or when the next input line is read.

's/REGEXP/REPLACEMENT/[FLAGS]' (substitute) Match the regular-expression against the content of the pattern space. If found, replace matched string with REPLACEMENT.

't LABEL' (test) Branch to LABEL only if there has been a successful 's'ubstitution since the last input line was read or conditional branch was taken. The LABEL may be omitted, in which case the next cycle is started.

'T LABEL' (test) Branch to LABEL only if there have been no successful 's'ubstitutions since the last input line was read or conditional branch was taken. The LABEL may be omitted, in which case the next cycle is started.

'v [VERSION]' (version) This command does nothing, but makes 'sed' fail if GNU 'sed' extensions are not supported, or if the requested version is not available.

'w filename' Write the pattern space to FILENAME.

'W filename' Write to the given filename the portion of the pattern space up to the first newline

'x' Exchange the contents of the hold and pattern spaces.

'y/src/dst/' Transliterate any characters in the pattern space which match any of the SOURCE-CHARS with the corresponding character in DEST-CHARS.

'z' (zap) This command empties the content of pattern space.

'#' A comment, until the next newline.

'{ CMD ; CMD ... }' Group several commands together.

'=' Print the current input line number (with a trailing newline).

': LABEL' Specify the location of LABEL for branch commands ('b', 't', 'T').

File: sed.info, Node: The "s" Command, Next: Common Commands, Prev: sed commands list, Up: sed scripts

3.3 The 's' Command

The 's' command (as in substitute) is probably the most important in 'sed' and has a lot of different options. The syntax of the 's' command is 's/REGEXP/REPLACEMENT/FLAGS'.

Its basic concept is simple: the 's' command attempts to match the pattern space against the supplied regular expression REGEXP; if the match is successful, then that portion of the pattern space which was matched is replaced with REPLACEMENT.

For details about REGEXP syntax *note Regular Expression Addresses: Regexp Addresses.

The REPLACEMENT can contain '\N' (N being a number from 1 to 9, inclusive) references, which refer to the portion of the match which is contained between the Nth '(' and its matching ')'. Also, the REPLACEMENT can contain unescaped '&' characters which reference the whole matched portion of the pattern space.

The '/' characters may be uniformly replaced by any other single character within any given 's' command. The '/' character (or whatever other character is used in its stead) can appear in the REGEXP or REPLACEMENT only if it is preceded by a '' character.

Finally, as a GNU 'sed' extension, you can include a special sequence made of a backslash and one of the letters 'L', 'l', 'U', 'u', or 'E'. The meaning is as follows:

'\L' Turn the replacement to lowercase until a '\U' or '\E' is found,

'\l' Turn the next character to lowercase,

'\U' Turn the replacement to uppercase until a '\L' or '\E' is found,

'\u' Turn the next character to uppercase,

'\E' Stop case conversion started by '\L' or '\U'.

When the 'g' flag is being used, case conversion does not propagate from one occurrence of the regular expression to another. For example, when the following command is executed with 'a-b-' in pattern space: s/(b?)-/x\u\1/g

the output is 'axxB'. When replacing the first '-', the '\u' sequence only affects the empty replacement of '\1'. It does not affect the 'x' character that is added to pattern space when replacing 'b-' with 'xB'.

On the other hand, '\l' and '\u' do affect the remainder of the replacement text if they are followed by an empty substitution. With 'a-b-' in pattern space, the following command: s/(b?)-/\u\1x/g

will replace '-' with 'X' (uppercase) and 'b-' with 'Bx'. If this behavior is undesirable, you can prevent it by adding a '\E' sequence--after '\1' in this case.

To include a literal '', '&', or newline in the final replacement, be sure to precede the desired '', '&', or newline in the REPLACEMENT with a ''.

The 's' command can be followed by zero or more of the following FLAGS:

'g' Apply the replacement to all matches to the REGEXP, not just the first.

'NUMBER' Only replace the NUMBERth match of the REGEXP.

 interaction in 's' command Note: the POSIX standard does not
 specify what should happen when you mix the 'g' and NUMBER
 modifiers, and currently there is no widely agreed upon meaning
 across 'sed' implementations.  For GNU 'sed', the interaction is
 defined to be: ignore matches before the NUMBERth, and then match
 and replace all matches from the NUMBERth on.

'p' If the substitution was made, then print the new pattern space.

 Note: when both the 'p' and 'e' options are specified, the relative
 ordering of the two produces very different results.  In general,
 'ep' (evaluate then print) is what you want, but operating the
 other way round can be useful for debugging.  For this reason, the
 current version of GNU 'sed' interprets specially the presence of
 'p' options both before and after 'e', printing the pattern space
 before and after evaluation, while in general flags for the 's'
 command show their effect just once.  This behavior, although
 documented, might change in future versions.

'w FILENAME' If the substitution was made, then write out the result to the named file. As a GNU 'sed' extension, two special values of FILENAME are supported: '/dev/stderr', which writes the result to the standard error, and '/dev/stdout', which writes to the standard output.(1)

'e' This command allows one to pipe input from a shell command into pattern space. If a substitution was made, the command that is found in pattern space is executed and pattern space is replaced with its output. A trailing newline is suppressed; results are undefined if the command to be executed contains a NUL character. This is a GNU 'sed' extension.

'I' 'i' The 'I' modifier to regular-expression matching is a GNU extension which makes 'sed' match REGEXP in a case-insensitive manner.

'M' 'm' The 'M' modifier to regular-expression matching is a GNU 'sed' extension which directs GNU 'sed' to match the regular expression in 'multi-line' mode. The modifier causes '^' and '$' to match respectively (in addition to the normal behavior) the empty string after a newline, and the empty string before a newline. There are special character sequences ('`' and ''') which always match the beginning or the end of the buffer. In addition, the period character does not match a new-line character in multi-line mode.

---------- Footnotes ----------

(1) This is equivalent to 'p' unless the '-i' option is being used.

File: sed.info, Node: Common Commands, Next: Other Commands, Prev: The "s" Command, Up: sed scripts

3.4 Often-Used Commands

If you use 'sed' at all, you will quite likely want to know these commands.

'#' [No addresses allowed.]

 The '#' character begins a comment; the comment continues until the
 next newline.

 If you are concerned about portability, be aware that some
 implementations of 'sed' (which are not POSIX conforming) may only
 support a single one-line comment, and then only when the very
 first character of the script is a '#'.

 Warning: if the first two characters of the 'sed' script are '#n',
 then the '-n' (no-autoprint) option is forced.  If you want to put
 a comment in the first line of your script and that comment begins
 with the letter 'n' and you do not want this behavior, then be sure
 to either use a capital 'N', or place at least one space before the
 'n'.

'q [EXIT-CODE]' Exit 'sed' without processing any more commands or input.

 Example: stop after printing the second line:
      $ seq 3 | sed 2q
      1
      2

 This command accepts only one address.  Note that the current
 pattern space is printed if auto-print is not disabled with the
 '-n' options.  The ability to return an exit code from the 'sed'
 script is a GNU 'sed' extension.

 See also the GNU 'sed' extension 'Q' command which quits silently
 without printing the current pattern space.

'd' Delete the pattern space; immediately start next cycle.

 Example: delete the second input line:
      $ seq 3 | sed 2d
      1
      3

'p' Print out the pattern space (to the standard output). This command is usually only used in conjunction with the '-n' command-line option.

 Example: print only the second input line:
      $ seq 3 | sed -n 2p
      2

'n' If auto-print is not disabled, print the pattern space, then, regardless, replace the pattern space with the next line of input. If there is no more input then 'sed' exits without processing any more commands.

 This command is useful to skip lines (e.g.  process every Nth
 line).

 Example: perform substitution on every 3rd line (i.e.  two 'n'
 commands skip two lines):
      $ seq 6 | sed 'n;n;s/./x/'
      1
      2
      x
      4
      5
      x

 GNU 'sed' provides an extension address syntax of FIRST~STEP to
 achieve the same result:

      $ seq 6 | sed '0~3s/./x/'
      1
      2
      x
      4
      5
      x

'{ COMMANDS }' A group of commands may be enclosed between '{' and '}' characters. This is particularly useful when you want a group of commands to be triggered by a single address (or address-range) match.

 Example: perform substitution then print the second input line:
      $ seq 3 | sed -n '2{s/2/X/ ; p}'
      X

File: sed.info, Node: Other Commands, Next: Programming Commands, Prev: Common Commands, Up: sed scripts

3.5 Less Frequently-Used Commands

Though perhaps less frequently used than those in the previous section, some very small yet useful 'sed' scripts can be built with these commands.

'y/SOURCE-CHARS/DEST-CHARS/' Transliterate any characters in the pattern space which match any of the SOURCE-CHARS with the corresponding character in DEST-CHARS.

 Example: transliterate 'a-j' into '0-9':
      $ echo hello world | sed 'y/abcdefghij/0123456789/'
      74llo worl3

 (The '/' characters may be uniformly replaced by any other single
 character within any given 'y' command.)

 Instances of the '/' (or whatever other character is used in its
 stead), '\', or newlines can appear in the SOURCE-CHARS or
 DEST-CHARS lists, provide that each instance is escaped by a '\'.
 The SOURCE-CHARS and DEST-CHARS lists _must_ contain the same
 number of characters (after de-escaping).

 See the 'tr' command from GNU coreutils for similar functionality.

'a TEXT' Appending TEXT after a line. This is a GNU extension to the standard 'a' command - see below for details.

 Example: Add the word 'hello' after the second line:
      $ seq 3 | sed '2a hello'
      1
      2
      hello
      3

 Leading whitespace after the 'a' command is ignored.  The text to
 add is read until the end of the line.

'a' 'TEXT' Appending TEXT after a line.

 Example: Add 'hello' after the second line (-| indicates printed
 output lines):
      $ seq 3 | sed '2a\
      hello'
      -|1
      -|2
      -|hello
      -|3

 The 'a' command queues the lines of text which follow this command
 (each but the last ending with a '\', which are removed from the
 output) to be output at the end of the current cycle, or when the
 next input line is read.

 As a GNU extension, this command accepts two addresses.

 Escape sequences in TEXT are processed, so you should use '\\' in
 TEXT to print a single backslash.

 The commands resume after the last line without a backslash ('\') -
 'world' in the following example:
      $ seq 3 | sed '2a\
      hello\
      world
      3s/./X/'
      -|1
      -|2
      -|hello
      -|world
      -|X

 As a GNU extension, the 'a' command and TEXT can be separated into
 two '-e' parameters, enabling easier scripting:
      $ seq 3 | sed -e '2a\' -e hello
      1
      2
      hello
      3

      $ sed -e '2a\' -e "$VAR"

'i TEXT' insert TEXT before a line. This is a GNU extension to the standard 'i' command - see below for details.

 Example: Insert the word 'hello' before the second line:
      $ seq 3 | sed '2i hello'
      1
      hello
      2
      3

 Leading whitespace after the 'i' command is ignored.  The text to
 add is read until the end of the line.

'i' 'TEXT' Immediately output the lines of text which follow this command.

 Example: Insert 'hello' before the second line (-| indicates
 printed output lines):
      $ seq 3 | sed '2i\
      hello'
      -|1
      -|hello
      -|2
      -|3

 As a GNU extension, this command accepts two addresses.

 Escape sequences in TEXT are processed, so you should use '\\' in
 TEXT to print a single backslash.

 The commands resume after the last line without a backslash ('\') -
 'world' in the following example:
      $ seq 3 | sed '2i\
      hello\
      world
      s/./X/'
      -|X
      -|hello
      -|world
      -|X
      -|X

 As a GNU extension, the 'i' command and TEXT can be separated into
 two '-e' parameters, enabling easier scripting:
      $ seq 3 | sed -e '2i\' -e hello
      1
      hello
      2
      3

      $ sed -e '2i\' -e "$VAR"

'c TEXT' Replaces the line(s) with TEXT. This is a GNU extension to the standard 'c' command - see below for details.

 Example: Replace the 2nd to 9th lines with the word 'hello':
      $ seq 10 | sed '2,9c hello'
      1
      hello
      10

 Leading whitespace after the 'c' command is ignored.  The text to
 add is read until the end of the line.

'c' 'TEXT' Delete the lines matching the address or address-range, and output the lines of text which follow this command.

 Example: Replace 2nd to 4th lines with the words 'hello' and
 'world' (-| indicates printed output lines):
      $ seq 5 | sed '2,4c\
      hello\
      world'
      -|1
      -|hello
      -|world
      -|5

 If no addresses are given, each line is replaced.

 A new cycle is started after this command is done, since the
 pattern space will have been deleted.  In the following example,
 the 'c' starts a new cycle and the substitution command is not
 performed on the replaced text:

      $ seq 3 | sed '2c\
      hello
      s/./X/'
      -|X
      -|hello
      -|X

 As a GNU extension, the 'c' command and TEXT can be separated into
 two '-e' parameters, enabling easier scripting:
      $ seq 3 | sed -e '2c\' -e hello
      1
      hello
      3

      $ sed -e '2c\' -e "$VAR"

'=' Print out the current input line number (with a trailing newline).

      $ printf '%s\n' aaa bbb ccc | sed =
      1
      aaa
      2
      bbb
      3
      ccc

 As a GNU extension, this command accepts two addresses.

'l N' Print the pattern space in an unambiguous form: non-printable characters (and the '' character) are printed in C-style escaped form; long lines are split, with a trailing '' character to indicate the split; the end of each line is marked with a '$'.

 N specifies the desired line-wrap length; a length of 0 (zero)
 means to never wrap long lines.  If omitted, the default as
 specified on the command line is used.  The N parameter is a GNU
 'sed' extension.

'r FILENAME'

 Reads file FILENAME.  Example:

      $ seq 3 | sed '2r/etc/hostname'
      1
      2
      fencepost.gnu.org
      3

 Queue the contents of FILENAME to be read and inserted into the
 output stream at the end of the current cycle, or when the next
 input line is read.  Note that if FILENAME cannot be read, it is
 treated as if it were an empty file, without any error indication.

 As a GNU 'sed' extension, the special value '/dev/stdin' is
 supported for the file name, which reads the contents of the
 standard input.

 As a GNU extension, this command accepts two addresses.  The file
 will then be reread and inserted on each of the addressed lines.

'w FILENAME' Write the pattern space to FILENAME. As a GNU 'sed' extension, two special values of FILENAME are supported: '/dev/stderr', which writes the result to the standard error, and '/dev/stdout', which writes to the standard output.(1)

 The file will be created (or truncated) before the first input line
 is read; all 'w' commands (including instances of the 'w' flag on
 successful 's' commands) which refer to the same FILENAME are
 output without closing and reopening the file.

'D' If pattern space contains no newline, start a normal new cycle as if the 'd' command was issued. Otherwise, delete text in the pattern space up to the first newline, and restart cycle with the resultant pattern space, without reading a new line of input.

'N' Add a newline to the pattern space, then append the next line of input to the pattern space. If there is no more input then 'sed' exits without processing any more commands.

 When '-z' is used, a zero byte (the ascii 'NUL' character) is added
 between the lines (instead of a new line).

 By default 'sed' does not terminate if there is no 'next' input
 line.  This is a GNU extension which can be disabled with
 '--posix'.  *Note N command on the last line: N_command_last_line.

'P' Print out the portion of the pattern space up to the first newline.

'h' Replace the contents of the hold space with the contents of the pattern space.

'H' Append a newline to the contents of the hold space, and then append the contents of the pattern space to that of the hold space.

'g' Replace the contents of the pattern space with the contents of the hold space.

'G' Append a newline to the contents of the pattern space, and then append the contents of the hold space to that of the pattern space.

'x' Exchange the contents of the hold and pattern spaces.

---------- Footnotes ----------

(1) This is equivalent to 'p' unless the '-i' option is being used.

File: sed.info, Node: Programming Commands, Next: Extended Commands, Prev: Other Commands, Up: sed scripts

3.6 Commands for 'sed' gurus

In most cases, use of these commands indicates that you are probably better off programming in something like 'awk' or Perl. But occasionally one is committed to sticking with 'sed', and these commands can enable one to write quite convoluted scripts.

': LABEL' [No addresses allowed.]

 Specify the location of LABEL for branch commands.  In all other
 respects, a no-op.

'b LABEL' Unconditionally branch to LABEL. The LABEL may be omitted, in which case the next cycle is started.

't LABEL' Branch to LABEL only if there has been a successful 's'ubstitution since the last input line was read or conditional branch was taken. The LABEL may be omitted, in which case the next cycle is started.

File: sed.info, Node: Extended Commands, Next: Multiple commands syntax, Prev: Programming Commands, Up: sed scripts

3.7 Commands Specific to GNU 'sed'

These commands are specific to GNU 'sed', so you must use them with care and only when you are sure that hindering portability is not evil. They allow you to check for GNU 'sed' extensions or to do tasks that are required quite often, yet are unsupported by standard 'sed's.

'e [COMMAND]' This command allows one to pipe input from a shell command into pattern space. Without parameters, the 'e' command executes the command that is found in pattern space and replaces the pattern space with the output; a trailing newline is suppressed.

 If a parameter is specified, instead, the 'e' command interprets it
 as a command and sends its output to the output stream.  The
 command can run across multiple lines, all but the last ending with
 a back-slash.

 In both cases, the results are undefined if the command to be
 executed contains a NUL character.

 Note that, unlike the 'r' command, the output of the command will
 be printed immediately; the 'r' command instead delays the output
 to the end of the current cycle.

'F' Print out the file name of the current input file (with a trailing newline).

'Q [EXIT-CODE]' This command accepts only one address.

 This command is the same as 'q', but will not print the contents of
 pattern space.  Like 'q', it provides the ability to return an exit
 code to the caller.

 This command can be useful because the only alternative ways to
 accomplish this apparently trivial function are to use the '-n'
 option (which can unnecessarily complicate your script) or
 resorting to the following snippet, which wastes time by reading
 the whole file without any visible effect:

      :eat
      $d       Quit silently on the last line
      N        Read another line, silently
      g        Overwrite pattern space each time to save memory
      b eat

'R FILENAME' Queue a line of FILENAME to be read and inserted into the output stream at the end of the current cycle, or when the next input line is read. Note that if FILENAME cannot be read, or if its end is reached, no line is appended, without any error indication.

 As with the 'r' command, the special value '/dev/stdin' is
 supported for the file name, which reads a line from the standard
 input.

'T LABEL' Branch to LABEL only if there have been no successful 's'ubstitutions since the last input line was read or conditional branch was taken. The LABEL may be omitted, in which case the next cycle is started.

'v VERSION' This command does nothing, but makes 'sed' fail if GNU 'sed' extensions are not supported, simply because other versions of 'sed' do not implement it. In addition, you can specify the version of 'sed' that your script requires, such as '4.0.5'. The default is '4.0' because that is the first version that implemented this command.

 This command enables all GNU extensions even if 'POSIXLY_CORRECT'
 is set in the environment.

'W FILENAME' Write to the given filename the portion of the pattern space up to the first newline. Everything said under the 'w' command about file handling holds here too.

'z' This command empties the content of pattern space. It is usually the same as 's/.*//', but is more efficient and works in the presence of invalid multibyte sequences in the input stream. POSIX mandates that such sequences are not matched by '.', so that there is no portable way to clear 'sed''s buffers in the middle of the script in most multibyte locales (including UTF-8 locales).

File: sed.info, Node: Multiple commands syntax, Prev: Extended Commands, Up: sed scripts

3.8 Multiple commands syntax

There are several methods to specify multiple commands in a 'sed' program.

Using newlines is most natural when running a sed script from a file (using the '-f' option).

On the command line, all 'sed' commands may be separated by newlines. Alternatively, you may specify each command as an argument to an '-e' option:

 $ seq 6 | sed '1d
 3d
 5d'
 2
 4
 6

 $ seq 6 | sed -e 1d -e 3d -e 5d
 2
 4
 6

A semicolon (';') may be used to separate most simple commands:

 $ seq 6 | sed '1d;3d;5d'
 2
 4
 6

The '{','}','b','t','T',':' commands can be separated with a semicolon (this is a non-portable GNU 'sed' extension).

 $ seq 4 | sed '{1d;3d}'
 2
 4

 $ seq 6 | sed '{1d;3d};5d'
 2
 4
 6

Labels used in 'b','t','T',':' commands are read until a semicolon. Leading and trailing whitespace is ignored. In the examples below the label is 'x'. The first example works with GNU 'sed'. The second is a portable equivalent. For more information about branching and labels *note Branching and flow control::.

 $ seq 3 | sed '/1/b x ; s/^/=/ ; :x ; 3d'
 1
 =2

 $ seq 3 | sed -e '/1/bx' -e 's/^/=/' -e ':x' -e '3d'
 1
 =2

3.8.1 Commands Requiring a newline

The following commands cannot be separated by a semicolon and require a newline:

'a','c','i' (append/change/insert)

 All characters following 'a','c','i' commands are taken as the text
 to append/change/insert.  Using a semicolon leads to undesirable
 results:

      $ seq 2 | sed '1aHello ; 2d'
      1
      Hello ; 2d
      2

 Separate the commands using '-e' or a newline:

      $ seq 2 | sed -e 1aHello -e 2d
      1
      Hello

      $ seq 2 | sed '1aHello
      2d'
      1
      Hello

 Note that specifying the text to add ('Hello') immediately after
 'a','c','i' is itself a GNU 'sed' extension.  A portable,
 POSIX-compliant alternative is:

      $ seq 2 | sed '1a\
      Hello
      2d'
      1
      Hello

'#' (comment)

 All characters following '#' until the next newline are ignored.

      $ seq 3 | sed '# this is a comment ; 2d'
      1
      2
      3


      $ seq 3 | sed '# this is a comment
      2d'
      1
      3

'r','R','w','W' (reading and writing files)

 The 'r','R','w','W' commands parse the filename until end of the
 line.  If whitespace, comments or semicolons are found, they will
 be included in the filename, leading to unexpected results:

      $ seq 2 | sed '1w hello.txt ; 2d'
      1
      2

      $ ls -log
      total 4
      -rw-rw-r-- 1 2 Jan 23 23:03 hello.txt ; 2d

      $ cat 'hello.txt ; 2d'
      1

 Note that 'sed' silently ignores read/write errors in
 'r','R','w','W' commands (such as missing files).  In the following
 example, 'sed' tries to read a file named ''hello.txt ; N''.  The
 file is missing, and the error is silently ignored:

      $ echo x | sed '1rhello.txt ; N'
      x

'e' (command execution)

 Any characters following the 'e' command until the end of the line
 will be sent to the shell.  If whitespace, comments or semicolons
 are found, they will be included in the shell command, leading to
 unexpected results:

      $ echo a | sed '1e touch foo#bar'
      a

      $ ls -1
      foo#bar

      $ echo a | sed '1e touch foo ; s/a/b/'
      sh: 1: s/a/b/: not found
      a

's///[we]' (substitute with 'e' or 'w' flags)

 In a substitution command, the 'w' flag writes the substitution
 result to a file, and the 'e' flag executes the subsitution result
 as a shell command.  As with the 'r/R/w/W/e' commands, these must
 be terminated with a newline.  If whitespace, comments or
 semicolons are found, they will be included in the shell command or
 filename, leading to unexpected results:

      $ echo a | sed 's/a/b/w1.txt#foo'
      b

      $ ls -1
      1.txt#foo

File: sed.info, Node: sed addresses, Next: sed regular expressions, Prev: sed scripts, Up: Top

4 Addresses: selecting lines

Menu:
Addresses overview:: Addresses overview
Numeric Addresses:: selecting lines by numbers
Regexp Addresses:: selecting lines by text matching
Range Addresses:: selecting a range of lines

File: sed.info, Node: Addresses overview, Next: Numeric Addresses, Up: sed addresses

4.1 Addresses overview

Addresses determine on which line(s) the 'sed' command will be executed. The following command replaces the word 'hello' with 'world' only on line 144:

 sed '144s/hello/world/' input.txt > output.txt

If no addresses are given, the command is performed on all lines. The following command replaces the word 'hello' with 'world' on all lines in the input file:

 sed 's/hello/world/' input.txt > output.txt

Addresses can contain regular expressions to match lines based on content instead of line numbers. The following command replaces the word 'hello' with 'world' only in lines containing the word 'apple':

 sed '/apple/s/hello/world/' input.txt > output.txt

An address range is specified with two addresses separated by a comma (','). Addresses can be numeric, regular expressions, or a mix of both. The following command replaces the word 'hello' with 'world' only in lines 4 to 17 (inclusive):

 sed '4,17s/hello/world/' input.txt > output.txt

Appending the '!' character to the end of an address specification (before the command letter) negates the sense of the match. That is, if the '!' character follows an address or an address range, then only lines which do not match the addresses will be selected. The following command replaces the word 'hello' with 'world' only in lines not containing the word 'apple':

 sed '/apple/!s/hello/world/' input.txt > output.txt

The following command replaces the word 'hello' with 'world' only in lines 1 to 3 and 18 till the last line of the input file (i.e. excluding lines 4 to 17):

 sed '4,17!s/hello/world/' input.txt > output.txt

File: sed.info, Node: Numeric Addresses, Next: Regexp Addresses, Prev: Addresses overview, Up: sed addresses

4.2 Selecting lines by numbers

Addresses in a 'sed' script can be in any of the following forms: 'NUMBER' Specifying a line number will match only that line in the input. (Note that 'sed' counts lines continuously across all input files unless '-i' or '-s' options are specified.)

'$' This address matches the last line of the last file of input, or the last line of each file when the '-i' or '-s' options are specified.

'FIRSTSTEP' This GNU extension matches every STEPth line starting with line FIRST. In particular, lines will be selected when there exists a non-negative N such that the current line-number equals FIRST + (N * STEP). Thus, one would use '12' to select the odd-numbered lines and '0~~2' for even-numbered lines; to pick every third line starting with the second, '2~~3' would be used; to pick every fifth line starting with the tenth, use '10~~5'; and '50~~0' is just an obscure way of saying '50'.

 The following commands demonstrate the step address usage:

      $ seq 10 | sed -n '0~4p'
      4
      8

      $ seq 10 | sed -n '1~3p'
      1
      4
      7
      10

File: sed.info, Node: Regexp Addresses, Next: Range Addresses, Prev: Numeric Addresses, Up: sed addresses

4.3 selecting lines by text matching

GNU 'sed' supports the following regular expression addresses. The default regular expression is *note Basic Regular Expression (BRE): BRE syntax. If '-E' or '-r' options are used, The regular expression should be in *note Extended Regular Expression (ERE): ERE syntax. syntax. *Note BRE vs ERE::.

'/REGEXP/' This will select any line which matches the regular expression REGEXP. If REGEXP itself includes any '/' characters, each must be escaped by a backslash ('').

 The following command prints lines in '/etc/passwd' which end with
 'bash'(1):

      sed -n '/bash$/p' /etc/passwd

 The empty regular expression '//' repeats the last regular
 expression match (the same holds if the empty regular expression is
 passed to the 's' command).  Note that modifiers to regular
 expressions are evaluated when the regular expression is compiled,
 thus it is invalid to specify them together with the empty regular
 expression.

'%REGEXP%' (The '%' may be replaced by any other single character.)

 This also matches the regular expression REGEXP, but allows one to
 use a different delimiter than '/'.  This is particularly useful if
 the REGEXP itself contains a lot of slashes, since it avoids the
 tedious escaping of every '/'.  If REGEXP itself includes any
 delimiter characters, each must be escaped by a backslash ('\').

 The following commands are equivalent.  They print lines which
 start with '/home/alice/documents/':

      sed -n '/^\/home\/alice\/documents\//p'
      sed -n '\%^/home/alice/documents/%p'
      sed -n '\;^/home/alice/documents/;p'

'/REGEXP/I' '%REGEXP%I' The 'I' modifier to regular-expression matching is a GNU extension which causes the REGEXP to be matched in a case-insensitive manner.

 In many other programming languages, a lower case 'i' is used for
 case-insensitive regular expression matching.  However, in 'sed'
 the 'i' is used for the insert command (*note insert command::).

 Observe the difference between the following examples.

 In this example, '/b/I' is the address: regular expression with 'I'
 modifier.  'd' is the delete command:

      $ printf "%s\n" a b c | sed '/b/Id'
      a
      c

 Here, '/b/' is the address: a regular expression.  'i' is the
 insert command.  'd' is the value to insert.  A line with 'd' is
 then inserted above the matched line:

      $ printf "%s\n" a b c | sed '/b/id'
      a
      d
      b
      c

'/REGEXP/M' '%REGEXP%M' The 'M' modifier to regular-expression matching is a GNU 'sed' extension which directs GNU 'sed' to match the regular expression in 'multi-line' mode. The modifier causes '^' and '$' to match respectively (in addition to the normal behavior) the empty string after a newline, and the empty string before a newline. There are special character sequences ('`' and ''') which always match the beginning or the end of the buffer. In addition, the period character does not match a new-line character in multi-line mode.

Regex addresses operate on the content of the current pattern space. If the pattern space is changed (for example with 's///' command) the regular expression matching will operate on the changed text.

In the following example, automatic printing is disabled with '-n'. The 's/2/X/' command changes lines containing '2' to 'X'. The command '/[0-9]/p' matches lines with digits and prints them. Because the second line is changed before the '/[0-9]/' regex, it will not match and will not be printed:

 $ seq 3 | sed -n 's/2/X/ ; /[0-9]/p'
 1
 3

---------- Footnotes ----------

(1) There are of course many other ways to do the same, e.g. grep 'bash $' /etc/passwd awk -F: '$ 7 == "/bin/bash"' /etc/passwd

File: sed.info, Node: Range Addresses, Prev: Regexp Addresses, Up: sed addresses

4.4 Range Addresses

An address range can be specified by specifying two addresses separated by a comma (','). An address range matches lines starting from where the first address matches, and continues until the second address matches (inclusively):

 $ seq 10 | sed -n '4,6p'
 4
 5
 6

If the second address is a REGEXP, then checking for the ending match will start with the line following the line which matched the first address: a range will always span at least two lines (except of course if the input stream ends).

 $ seq 10 | sed -n '4,/[0-9]/p'
 4
 5

If the second address is a NUMBER less than (or equal to) the line matching the first address, then only the one line is matched:

 $ seq 10 | sed -n '4,1p'
 4

GNU 'sed' also supports some special two-address forms; all these are GNU extensions: '0,/REGEXP/' A line number of '0' can be used in an address specification like '0,/REGEXP/' so that 'sed' will try to match REGEXP in the first input line too. In other words, '0,/REGEXP/' is similar to '1,/REGEXP/', except that if ADDR2 matches the very first line of input the '0,/REGEXP/' form will consider it to end the range, whereas the '1,/REGEXP/' form will match the beginning of its range and hence make the range span up to the second occurrence of the regular expression.

 Note that this is the only place where the '0' address makes sense;
 there is no 0-th line and commands which are given the '0' address
 in any other way will give an error.

 The following examples demonstrate the difference between starting
 with address 1 and 0:

      $ seq 10 | sed -n '1,/[0-9]/p'
      1
      2

      $ seq 10 | sed -n '0,/[0-9]/p'
      1

'ADDR1,+N' Matches ADDR1 and the N lines following ADDR1.

      $ seq 10 | sed -n '6,+2p'
      6
      7
      8

 ADDR1 can be a line number or a regular expression.

'ADDR1,~N' Matches ADDR1 and the lines following ADDR1 until the next line whose input line number is a multiple of N. The following command prints starting at line 6, until the next line which is a multiple of 4 (i.e. line 8):

      $ seq 10 | sed -n '6,~4p'
      6
      7
      8

 ADDR1 can be a line number or a regular expression.

File: sed.info, Node: sed regular expressions, Next: advanced sed, Prev: sed addresses, Up: Top

5 Regular Expressions: selecting text

Menu:
Regular Expressions Overview:: Overview of Regular expression in 'sed'
BRE vs ERE:: Basic (BRE) and extended (ERE) regular expression syntax
BRE syntax:: Overview of basic regular expression syntax
ERE syntax:: Overview of extended regular expression syntax
Character Classes and Bracket Expressions::
regexp extensions:: Additional regular expression commands
Back-references and Subexpressions:: Back-references and Subexpressions
Escapes:: Specifying special characters
Locale Considerations:: Multibyte characters and locale considrations

File: sed.info, Node: Regular Expressions Overview, Next: BRE vs ERE, Up: sed regular expressions

5.1 Overview of regular expression in 'sed'

To know how to use 'sed', people should understand regular expressions ("regexp" for short). A regular expression is a pattern that is matched against a subject string from left to right. Most characters are "ordinary": they stand for themselves in a pattern, and match the corresponding characters. Regular expressions in 'sed' are specified between two slashes.

The following command prints lines containing the word 'hello':

 sed -n '/hello/p'

The above example is equivalent to this 'grep' command:

 grep 'hello'

The power of regular expressions comes from the ability to include alternatives and repetitions in the pattern. These are encoded in the pattern by the use of "special characters", which do not stand for themselves but instead are interpreted in some special way.

The character '^' (caret) in a regular expression matches the beginning of the line. The character '.' (dot) matches any single character. The following 'sed' command matches and prints lines which start with the letter 'b', followed by any single character, followed by the letter 'd':

 $ printf "%s\n" abode bad bed bit bid byte body | sed -n '/^b.d/p'
 bad
 bed
 bid
 body

The following sections explain the meaning and usage of special characters in regular expressions.

File: sed.info, Node: BRE vs ERE, Next: BRE syntax, Prev: Regular Expressions Overview, Up: sed regular expressions

5.2 Basic (BRE) and extended (ERE) regular expression

Basic and extended regular expressions are two variations on the syntax of the specified pattern. Basic Regular Expression (BRE) syntax is the default in 'sed' (and similarly in 'grep'). Use the POSIX-specified '-E' option ('-r', '--regexp-extended') to enable Extended Regular Expression (ERE) syntax.

In GNU 'sed', the only difference between basic and extended regular expressions is in the behavior of a few special characters: '?', '+', parentheses, braces ('{}'), and '|'.

With basic (BRE) syntax, these characters do not have special meaning unless prefixed with a backslash (''); While with extended (ERE) syntax it is reversed: these characters are special unless they are prefixed with backslash ('').

Desired pattern Basic (BRE) Syntax Extended (ERE) Syntax

literal '+' (plus $echo 'a+b=c' > foo$ echo 'a+b=c' > foo sign) $sed -n '/a+b/p' foo$ sed -E -n '/a+b/p' foo a+b=c a+b=c

One or more 'a' $echo aab > foo$ echo aab > foo characters $sed -n '/a\+b/p' foo$ sed -E -n '/a+b/p' foo followed by 'b' aab aab (plus sign as
special meta-character)

File: sed.info, Node: BRE syntax, Next: ERE syntax, Prev: BRE vs ERE, Up: sed regular expressions

5.3 Overview of basic regular expression syntax

Here is a brief description of regular expression syntax as used in 'sed'.

'CHAR' A single ordinary character matches itself.

'' Matches a sequence of zero or more instances of matches for the preceding regular expression, which must be an ordinary character, a special character preceded by '', a '.', a grouped regexp (see below), or a bracket expression. As a GNU extension, a postfixed regular expression can also be followed by ''; for example, 'a**' is equivalent to 'a*'. POSIX 1003.1-2001 says that '*' stands for itself when it appears at the start of a regular expression or subexpression, but many nonGNU implementations do not support this and portable scripts should instead use '*' in these contexts. '.' Matches any character, including newline.

'^' Matches the null string at beginning of the pattern space, i.e. what appears after the circumflex must appear at the beginning of the pattern space.

 In most scripts, pattern space is initialized to the content of
 each line (*note How 'sed' works: Execution Cycle.).  So, it is a
 useful simplification to think of '^#include' as matching only
 lines where '#include' is the first thing on line--if there are
 spaces before, for example, the match fails.  This simplification
 is valid as long as the original content of pattern space is not
 modified, for example with an 's' command.

 '^' acts as a special character only at the beginning of the
 regular expression or subexpression (that is, after '\(' or '\|').
 Portable scripts should avoid '^' at the beginning of a
 subexpression, though, as POSIX allows implementations that treat
 '^' as an ordinary character in that context.

' $' It is the same as '^', but refers to end of pattern space. '$ ' also acts as a special character only at the end of the regular expression or subexpression (that is, before ')' or '|'), and its use at the end of a subexpression is not portable.

'[LIST]' '[^LIST]' Matches any single character in LIST: for example, '[aeiou]' matches all vowels. A list may include sequences like 'CHAR1-CHAR2', which matches any character between (inclusive) CHAR1 and CHAR2. *Note Character Classes and Bracket Expressions::.

'+' As '*', but matches one or more. It is a GNU extension.

'?' As '*', but only matches zero or one. It is a GNU extension.

'{I}' As '*', but matches exactly I sequences (I is a decimal integer; for portability, keep it between 0 and 255 inclusive).

'{I,J}' Matches between I and J, inclusive, sequences.

'{I,}' Matches more than or equal to I sequences.

'(REGEXP)' Groups the inner REGEXP as a whole, this is used to:

    * Apply postfix operators, like '\(abcd\)*': this will search
      for zero or more whole sequences of 'abcd', while 'abcd*'
      would search for 'abc' followed by zero or more occurrences of
      'd'.  Note that support for '\(abcd\)*' is required by POSIX
      1003.1-2001, but many non-GNU implementations do not support
      it and hence it is not universally portable.

    * Use back references (see below).

'REGEXP1|REGEXP2' Matches either REGEXP1 or REGEXP2. Use parentheses to use complex alternative regular expressions. The matching process tries each alternative in turn, from left to right, and the first one that succeeds is used. It is a GNU extension.

'REGEXP1REGEXP2' Matches the concatenation of REGEXP1 and REGEXP2. Concatenation binds more tightly than '|', '^', and '$', but less tightly than the other regular expression operators.

'\DIGIT' Matches the DIGIT-th '(...)' parenthesized subexpression in the regular expression. This is called a "back reference". Subexpressions are implicitly numbered by counting occurrences of '(' left-to-right.

'\n' Matches the newline character.

'\CHAR' Matches CHAR, where CHAR is one of '$', '*', '.', '[', '', or '^'. Note that the only C-like backslash sequences that you can portably assume to be interpreted are '\n' and '\'; in particular '\t' is not portable, and matches a 't' under most implementations of 'sed', rather than a tab character.

Note that the regular expression matcher is greedy, i.e., matches are attempted from left to right and, if two or more matches are possible starting at the same character, it selects the longest.

Examples: 'abcdef' Matches 'abcdef'.

'a*b' Matches zero or more 'a's followed by a single 'b'. For example, 'b' or 'aaaaab'.

'a?b' Matches 'b' or 'ab'.

'a+b+' Matches one or more 'a's followed by one or more 'b's: 'ab' is the shortest possible match, but other examples are 'aaaab' or 'abbbbb' or 'aaaaaabbbbbbb'.

'.*' '.+' These two both match all the characters in a string; however, the first matches every string (including the empty string), while the second matches only strings containing at least one character.

'^main.(.)' This matches a string starting with 'main', followed by an opening and closing parenthesis. The 'n', '(' and ')' need not be adjacent.

'^#' This matches a string beginning with '#'.

'\$' This matches a string ending with a single backslash. The regexp contains two backslashes for escaping.

'$' Instead, this matches a string consisting of a single dollar sign, because it is escaped.

'[a-zA-Z0-9]' In the C locale, this matches any ASCII letters or digits.

'[^ '']+' (Here '' stands for a single tab character.) This matches a string of one or more characters, none of which is a space or a tab. Usually this means a word.

'^(.*)\n\1$' This matches a string consisting of two equal substrings separated by a newline.

'.{9}A$' This matches nine characters followed by an 'A' at the end of a line.

'^.{15}A' This matches the start of a string that contains 16 characters, the last of which is an 'A'.

File: sed.info, Node: ERE syntax, Next: Character Classes and Bracket Expressions, Prev: BRE syntax, Up: sed regular expressions

5.4 Overview of extended regular expression syntax

The only difference between basic and extended regular expressions is in the behavior of a few characters: '?', '+', parentheses, braces ('{}'), and '|'. While basic regular expressions require these to be escaped if you want them to behave as special characters, when using extended regular expressions you must escape them if you want them to match a literal character. '|' is special here because '|' is a GNU extension

standard basic regular expressions do not provide its functionality.

Examples: 'abc?' becomes 'abc?' when using extended regular expressions. It matches the literal string 'abc?'.

'c+' becomes 'c+' when using extended regular expressions. It matches one or more 'c's.

'a{3,}' becomes 'a{3,}' when using extended regular expressions. It matches three or more 'a's.

'(abc){2,3}' becomes '(abc){2,3}' when using extended regular expressions. It matches either 'abcabc' or 'abcabcabc'.

'(abc*)\1' becomes '(abc*)\1' when using extended regular expressions. Backreferences must still be escaped when using extended regular expressions.

'a|b' becomes 'a|b' when using extended regular expressions. It matches 'a' or 'b'.

File: sed.info, Node: Character Classes and Bracket Expressions, Next: regexp extensions, Prev: ERE syntax, Up: sed regular expressions

5.5 Character Classes and Bracket Expressions

A "bracket expression" is a list of characters enclosed by '[' and ']'. It matches any single character in that list; if the first character of the list is the caret '^', then it matches any character not in the list. For example, the following command replaces the words 'gray' or 'grey' with 'blue':

 sed  's/gr[ae]y/blue/'

Bracket expressions can be used in both *note basic: BRE syntax. and *note extended: ERE syntax. regular expressions (that is, with or without the '-E'/'-r' options).

Within a bracket expression, a "range expression" consists of two characters separated by a hyphen. It matches any single character that sorts between the two characters, inclusive. In the default C locale, the sorting sequence is the native character order; for example, '[a-d]' is equivalent to '[abcd]'.

Finally, certain named classes of characters are predefined within bracket expressions, as follows.

These named classes must be used inside brackets themselves. Correct usage: $ echo 1 | sed 's/[[:digit:]]/X/' X

Incorrect usage is rejected by newer 'sed' versions. Older versions accepted it but treated it as a single bracket expression (which is equivalent to '[dgit:]', that is, only the characters D/G/I/T/:): # current GNU sed versions - incorrect usage rejected $ echo 1 | sed 's/[:digit:]/X/' sed: character class syntax is [[:space:]], not [:space:]

 # older GNU sed versions
 $ echo 1 | sed 's/[:digit:]/X/'
 1

'[:alnum:]' Alphanumeric characters: '[:alpha:]' and '[:digit:]'; in the 'C' locale and ASCII character encoding, this is the same as '[0-9A-Za-z]'.

'[:alpha:]' Alphabetic characters: '[:lower:]' and '[:upper:]'; in the 'C' locale and ASCII character encoding, this is the same as '[A-Za-z]'.

'[:blank:]' Blank characters: space and tab.

'[:cntrl:]' Control characters. In ASCII, these characters have octal codes 000 through 037, and 177 (DEL). In other character sets, these are the equivalent characters, if any.

'[:digit:]' Digits: '0 1 2 3 4 5 6 7 8 9'.

'[:graph:]' Graphical characters: '[:alnum:]' and '[:punct:]'.

'[:lower:]' Lower-case letters; in the 'C' locale and ASCII character encoding, this is 'a b c d e f g h i j k l m n o p q r s t u v w x y z'.

'[:print:]' Printable characters: '[:alnum:]', '[:punct:]', and space.

'[:punct:]' Punctuation characters; in the 'C' locale and ASCII character encoding, this is '! " # $ % & ' ( ) * + , - . / : ; < = > ? @ [
] ^ _ ` { | } ~'.

'[:space:]' Space characters: in the 'C' locale, this is tab, newline, vertical tab, form feed, carriage return, and space.

'[:upper:]' Upper-case letters: in the 'C' locale and ASCII character encoding, this is 'A B C D E F G H I J K L M N O P Q R S T U V W X Y Z'.

'[:xdigit:]' Hexadecimal digits: '0 1 2 3 4 5 6 7 8 9 A B C D E F a b c d e f'.

Note that the brackets in these class names are part of the symbolic names, and must be included in addition to the brackets delimiting the bracket expression.

Most meta-characters lose their special meaning inside bracket expressions:

']' ends the bracket expression if it's not the first list item. So, if you want to make the ']' character a list item, you must put it first.

'-' represents the range if it's not first or last in a list or the ending point of a range.

'^' represents the characters not in the list. If you want to make the '^' character a list item, place it anywhere but first.

TODO: incorporate this paragraph (copied verbatim from BRE section).

The characters '$', '', '.', '[', and '' are normally not special within LIST. For example, '[*]' matches either '' or '', because the '' is not special here. However, strings like '[.ch.]', '[=a=]', and '[:space:]' are special within LIST and represent collating symbols, equivalence classes, and character classes, respectively, and '[' is therefore special within LIST when it is followed by '.', '=', or ':'. Also, when not in 'POSIXLY_CORRECT' mode, special escapes like '\n' and '\t' are recognized within LIST. *Note Escapes::.

'[.' represents the open collating symbol.

'.]' represents the close collating symbol.

'[=' represents the open equivalence class.

'=]' represents the close equivalence class.

'[:' represents the open character class symbol, and should be followed by a valid character class name.

':]' represents the close character class symbol.

File: sed.info, Node: regexp extensions, Next: Back-references and Subexpressions, Prev: Character Classes and Bracket Expressions, Up: sed regular expressions

5.6 regular expression extensions

The following sequences have special meaning inside regular expressions (used in *note addresses: Regexp Addresses. and the 's' command).

These can be used in both *note basic: BRE syntax. and *note extended: ERE syntax. regular expressions (that is, with or without the '-E'/'-r' options).

'\w' Matches any "word" character. A "word" character is any letter or digit or the underscore character.

      $ echo "abc %-= def." | sed 's/\w/X/g'
      XXX %-= XXX.

'\W' Matches any "non-word" character.

      $ echo "abc %-= def." | sed 's/\W/X/g'
      abcXXXXXdefX

'\b' Matches a word boundary; that is it matches if the character to the left is a "word" character and the character to the right is a "non-word" character, or vice-versa.

      $ echo "abc %-= def." | sed 's/\b/X/g'
      XabcX %-= XdefX.

'\B' Matches everywhere but on a word boundary; that is it matches if the character to the left and the character to the right are either both "word" characters or both "non-word" characters.

      $ echo "abc %-= def." | sed 's/\B/X/g'
      aXbXc X%X-X=X dXeXf.X

'\s' Matches whitespace characters (spaces and tabs). Newlines embedded in the pattern/hold spaces will also match:

      $ echo "abc %-= def." | sed 's/\s/X/g'
      abcX%-=Xdef.

'\S' Matches non-whitespace characters.

      $ echo "abc %-= def." | sed 's/\S/X/g'
      XXX XXX XXXX

'<' Matches the beginning of a word.

      $ echo "abc %-= def." | sed 's/\</X/g'
      Xabc %-= Xdef.

'>' Matches the end of a word.

      $ echo "abc %-= def." | sed 's/\>/X/g'
      abcX %-= defX.

'`' Matches only at the start of pattern space. This is different from '^' in multi-line mode.

 Compare the following two examples:

      $ printf "a\nb\nc\n" | sed 'N;N;s/^/X/gm'
      Xa
      Xb
      Xc

      $ printf "a\nb\nc\n" | sed 'N;N;s/\`/X/gm'
      Xa
      b
      c

''' Matches only at the end of pattern space. This is different from '$' in multi-line mode.

File: sed.info, Node: Back-references and Subexpressions, Next: Escapes, Prev: regexp extensions, Up: sed regular expressions

5.7 Back-references and Subexpressions

"back-references" are regular expression commands which refer to a previous part of the matched regular expression. Back-references are specified with backslash and a single digit (e.g. '\1'). The part of the regular expression they refer to is called a "subexpression", and is designated with parentheses.

Back-references and subexpressions are used in two cases: in the regular expression search pattern, and in the REPLACEMENT part of the 's' command (*note Regular Expression Addresses: Regexp Addresses. and *note The "s" Command::).

In a regular expression pattern, back-references are used to match the same content as a previously matched subexpression. In the following example, the subexpression is '.' - any single character (being surrounded by parentheses makes it a subexpression). The back-reference '\1' asks to match the same content (same character) as the sub-expression.

The command below matches words starting with any character, followed by the letter 'o', followed by the same character as the first.

 $ sed -E -n '/^(.)o\1$/p' /usr/share/dict/words
 bob
 mom
 non
 pop
 sos
 tot
 wow

Multiple subexpressions are automatically numbered from left-to-right. This command searches for 6-letter palindromes (the first three letters are 3 subexpressions, followed by 3 back-references in reverse order):

 $ sed -E -n '/^(.)(.)(.)\3\2\1$/p' /usr/share/dict/words
 redder

In the 's' command, back-references can be used in the REPLACEMENT part to refer back to subexpressions in the REGEXP part.

The following example uses two subexpressions in the regular expression to match two space-separated words. The back-references in the REPLACEMENT part prints the words in a different order:

 $ echo "James Bond" | sed -E 's/(.*) (.*)/The name is \2, \1 \2./'
 The name is Bond, James Bond.

When used with alternation, if the group does not participate in the match then the back-reference makes the whole match fail. For example, 'a(.)|b\1' will not match 'ba'. When multiple regular expressions are given with '-e' or from a file ('-f FILE'), back-references are local to each expression.

File: sed.info, Node: Escapes, Next: Locale Considerations, Prev: Back-references and Subexpressions, Up: sed regular expressions

5.8 Escape Sequences - specifying special characters

Until this chapter, we have only encountered escapes of the form '^', which tell 'sed' not to interpret the circumflex as a special character, but rather to take it literally. For example, '*' matches a single asterisk rather than zero or more backslashes.

This chapter introduces another kind of escape(1)--that is, escapes that are applied to a character or sequence of characters that ordinarily are taken literally, and that 'sed' replaces with a special character. This provides a way of encoding non-printable characters in patterns in a visible manner. There is no restriction on the appearance of non-printing characters in a 'sed' script but when a script is being prepared in the shell or by text editing, it is usually easier to use one of the following escape sequences than the binary character it represents:

The list of these escapes is:

'\a' Produces or matches a BEL character, that is an "alert" (ASCII 7).

'\f' Produces or matches a form feed (ASCII 12).

'\n' Produces or matches a newline (ASCII 10).

'\r' Produces or matches a carriage return (ASCII 13).

'\t' Produces or matches a horizontal tab (ASCII 9).

'\v' Produces or matches a so called "vertical tab" (ASCII 11).

'\cX' Produces or matches 'CONTROL-X', where X is any character. The precise effect of '\cX' is as follows: if X is a lower case letter, it is converted to upper case. Then bit 6 of the character (hex 40) is inverted. Thus '\cz' becomes hex 1A, but '\c{' becomes hex 3B, while '\c;' becomes hex 7B.

'\dXXX' Produces or matches a character whose decimal ASCII value is XXX.

'\oXXX' Produces or matches a character whose octal ASCII value is XXX.

'\xXX' Produces or matches a character whose hexadecimal ASCII value is XX.

'\b' (backspace) was omitted because of the conflict with the existing "word boundary" meaning.

5.8.1 Escaping Precedence

GNU 'sed' processes escape sequences before passing the text onto the regular-expression matching of the 's///' command and Address matching. Thus the follwing two commands are equivalent ('0x5e' is the hexadecimal ASCII value of the character '^'):

 $ echo 'a^c' | sed 's/^/b/'
 ba^c

 $ echo 'a^c' | sed 's/\x5e/b/'
 ba^c

As are the following ('0x5b','0x5d' are the hexadecimal ASCII values of '[',']', respectively):

 $ echo abc | sed 's/[a]/x/'
 Xbc
 $ echo abc | sed 's/\x5ba\x5d/x/'
 Xbc

However it is recommended to avoid such special characters due to unexpected edge-cases. For example, the following are not equivalent:

 $ echo 'a^c' | sed 's/\^/b/'
 abc

 $ echo 'a^c' | sed 's/\\\x5e/b/'
 a^c

---------- Footnotes ----------

(1) All the escapes introduced here are GNU extensions, with the exception of '\n'. In basic regular expression mode, setting 'POSIXLY_CORRECT' disables them inside bracket expressions.

File: sed.info, Node: Locale Considerations, Prev: Escapes, Up: sed regular expressions

5.9 Multibyte characters and Locale Considerations

GNU 'sed' processes valid multibyte characters in multibyte locales (e.g. 'UTF-8'). (1)

The following example uses the Greek letter Capital Sigma (U+03A3, Unicode code point '0x03A3'). In a 'UTF-8' locale, 'sed' correctly processes the Sigma as one character despite it being 2 octets (bytes):

 $ locale | grep LANG
 LANG=en_US.UTF-8

 $ printf 'a\u03A3b'
 aU+03A3b

 $ printf 'a\u03A3b' | sed 's/./X/g'
 XXX

 $ printf 'a\u03A3b' | od -tx1 -An
  61 ce a3 62

To force 'sed' to process octets separately, use the 'C' locale (also known as the 'POSIX' locale):

 $ printf 'a\u03A3b' | LC_ALL=C sed 's/./X/g'
 XXXX

5.9.1 Invalid multibyte characters

'sed''s regular expressions do not match invalid multibyte sequences in a multibyte locale.

In the following examples, the ascii value '0xCE' is an incomplete multibyte character (shown here as U+FFFD). The regular expression '.' does not match it:

 $ printf 'a\xCEb\n'
 aU+FFFDe

 $ printf 'a\xCEb\n' | sed 's/./X/g'
 XU+FFFDX

 $ printf 'a\xCEc\n' | sed 's/./X/g' | od -tx1c -An
   58  ce  58  0a
    X      X   \n

Similarly, the 'catch-all' regular expression '.*' does not match the entire line:

 $ printf 'a\xCEc\n' | sed 's/.*//' | od -tx1c -An
   ce  63  0a
        c  \n

GNU 'sed' offers the special 'z' command to clear the current pattern space regardless of invalid multibyte characters (i.e. it works like 's/.*//' but also removes invalid multibyte characters):

 $ printf 'a\xCEc\n' | sed 'z' | od -tx1c -An
    0a
    \n

Alternatively, force the 'C' locale to process each octet separately (every octet is a valid character in the 'C' locale):

 $ printf 'a\xCEc\n' | LC_ALL=C sed 's/.*//' | od -tx1c -An
   0a
   \n

'sed''s inability to process invalid multibyte characters can be used to detect such invalid sequences in a file. In the following examples, the '\xCE\xCE' is an invalid multibyte sequence, while '\xCE\A3' is a valid multibyte sequence (of the Greek Sigma character).

The following 'sed' program removes all valid characters using 's/.//g'. Any content left in the pattern space (the invalid characters) are added to the hold space using the 'H' command. On the last line ('$'), the hold space is retrieved ('x'), newlines are removed ('s/\n//g'), and any remaining octets are printed unambiguously ('l'). Thus, any invalid multibyte sequences are printed as octal values:

 $ printf 'ab\nc\n\xCE\xCEde\n\xCE\xA3f\n' > invalid.txt

 $ cat invalid.txt
 ab
 c
 U+FFFDU+FFFDde
 U+03A3f

 $ sed -n 's/.//g ; H ; ${x;s/\n//g;l}' invalid.txt
 \316\316$

With a few more commands, 'sed' can print the exact line number corresponding to each invalid characters (line 3). These characters can then be removed by forcing the 'C' locale and using octal escape sequences:

 $ sed -n 's/.//g;=;l' invalid.txt | paste - -  | awk '$2!="$"'
 3       \316\316$

 $ LC_ALL=C sed '3s/\o316\o316//' invalid.txt > fixed.txt

5.9.2 Upper/Lower case conversion

GNU 'sed''s substitute command ('s') supports upper/lower case conversions using '\U','\L' codes. These conversions support multibyte characters:

 $ printf 'ABC\u03a3\n'
 ABCU+03A3

 $ printf 'ABC\u03a3\n' | sed 's/.*/\L&/'
 abcU+03C3

*Note The "s" Command::.

5.9.3 Multibyte regexp character classes

In other locales, the sorting sequence is not specified, and '[a-d]' might be equivalent to '[abcd]' or to '[aBbCcDd]', or it might fail to match any character, or the set of characters that it matches might even be erratic. To obtain the traditional interpretation of bracket expressions, you can use the 'C' locale by setting the 'LC_ALL' environment variable to the value 'C'.

 # TODO: is there any real-world system/locale where 'A'
 #       is replaced by '-' ?
 $ echo A | sed 's/[a-z]/-/'
 A

Their interpretation depends on the 'LC_CTYPE' locale; for example, '[[:alnum:]]' means the character class of numbers and letters in the current locale.

TODO: show example of collation

 # TODO: this works on glibc systems, not on musl-libc/freebsd/macosx.
 $ printf 'cliché\n' | LC_ALL=fr_FR.utf8 sed 's/[[=e=]]/X/g'
 clichX

---------- Footnotes ----------

(1) Some regexp edge-cases depends on the operating system and libc implementation. The examples shown are known to work as-expected on GNU/Linux systems using glibc.

File: sed.info, Node: advanced sed, Next: Examples, Prev: sed regular expressions, Up: Top

6 Advanced 'sed': cycles and buffers

Menu:
Execution Cycle:: How 'sed' works
Hold and Pattern Buffers::
Multiline techniques:: Using D,G,H,N,P to process multiple lines
Branching and flow control::

File: sed.info, Node: Execution Cycle, Next: Hold and Pattern Buffers, Up: advanced sed

6.1 How 'sed' Works

'sed' maintains two data buffers: the active pattern space, and the auxiliary hold space. Both are initially empty.

'sed' operates by performing the following cycle on each line of input: first, 'sed' reads one line from the input stream, removes any trailing newline, and places it in the pattern space. Then commands are executed; each command can have an address associated to it: addresses are a kind of condition code, and a command is only executed if the condition is verified before the command is to be executed.

When the end of the script is reached, unless the '-n' option is in use, the contents of pattern space are printed out to the output stream, adding back the trailing newline if it was removed.(1) Then the next cycle starts for the next input line.

Unless special commands (like 'D') are used, the pattern space is deleted between two cycles. The hold space, on the other hand, keeps its data between cycles (see commands 'h', 'H', 'x', 'g', 'G' to move data between both buffers).

---------- Footnotes ----------

(1) Actually, if 'sed' prints a line without the terminating newline, it will nevertheless print the missing newline as soon as more text is sent to the same output stream, which gives the "least expected surprise" even though it does not make commands like 'sed -n p' exactly identical to 'cat'.

File: sed.info, Node: Hold and Pattern Buffers, Next: Multiline techniques, Prev: Execution Cycle, Up: advanced sed

6.2 Hold and Pattern Buffers

TODO

File: sed.info, Node: Multiline techniques, Next: Branching and flow control, Prev: Hold and Pattern Buffers, Up: advanced sed

6.3 Multiline techniques - using D,G,H,N,P to process multiple lines

Multiple lines can be processed as one buffer using the 'D','G','H','N','P'. They are similar to their lowercase counterparts ('d','g', 'h','n','p'), except that these commands append or subtract data while respecting embedded newlines - allowing adding and removing lines from the pattern and hold spaces.

They operate as follows: 'D' deletes line from the pattern space until the first newline, and restarts the cycle.

'G' appends line from the hold space to the pattern space, with a newline before it.

'H' appends line from the pattern space to the hold space, with a newline before it.

'N' appends line from the input file to the pattern space.

'P' prints line from the pattern space until the first newline.

The following example illustrates the operation of 'N' and 'D' commands:

 $ seq 6 | sed -n 'N;l;D'
 1\n2$
 2\n3$
 3\n4$
 4\n5$
 5\n6$

'sed' starts by reading the first line into the pattern space (i.e. '1').
At the beginning of every cycle, the 'N' command appends a newline and the next line to the pattern space (i.e. '1', '\n', '2' in the first cycle).
The 'l' command prints the content of the pattern space unambiguously.
The 'D' command then removes the content of pattern space up to the first newline (leaving '2' at the end of the first cycle).
At the next cycle the 'N' command appends a newline and the next input line to the pattern space (e.g. '2', '\n', '3').

A common technique to process blocks of text such as paragraphs (instead of line-by-line) is using the following construct:

 sed '/./{H;$!d} ; x ; s/REGEXP/REPLACEMENT/'

The first expression, '/./{H;$!d}' operates on all non-empty lines, and adds the current line (in the pattern space) to the hold space. On all lines except the last, the pattern space is deleted and the cycle is restarted.
The other expressions 'x' and 's' are executed only on empty lines (i.e. paragraph separators). The 'x' command fetches the accumulated lines from the hold space back to the pattern space. The 's///' command then operates on all the text in the paragraph (including the embedded newlines).

The following example demonstrates this technique: $ cat input.txt a a a aa aaa aaaa aaaa aa aaaa aaa aaa

 bbbb bbb bbb
 bb bb bbb bb
 bbbbbbbb bbb

 ccc ccc cccc
 cccc ccccc c
 cc cc cc cc

 $ sed '/./{H;$!d} ; x ; s/^/\nSTART-->/ ; s/$/\n<--END/' input.txt

 START-->
 a a a aa aaa
 aaaa aaaa aa
 aaaa aaa aaa
 <--END

 START-->
 bbbb bbb bbb
 bb bb bbb bb
 bbbbbbbb bbb
 <--END

 START-->
 ccc ccc cccc
 cccc ccccc c
 cc cc cc cc
 <--END

For more annotated examples, *note Text search across multiple lines:: and *note Line length adjustment::.

File: sed.info, Node: Branching and flow control, Prev: Multiline techniques, Up: advanced sed

6.4 Branching and Flow Control

The branching commands 'b', 't', and 'T' enable changing the flow of 'sed' programs.

By default, 'sed' reads an input line into the pattern buffer, then continues to processes all commands in order. Commands without addresses affect all lines. Commands with addresses affect only matching lines. *Note Execution Cycle:: and *note Addresses overview::.

'sed' does not support a typical 'if/then' construct. Instead, some commands can be used as conditionals or to change the default flow control:

'd' delete (clears) the current pattern space, and restart the program cycle without processing the rest of the commands and without printing the pattern space.

'D' delete the contents of the pattern space up to the first newline, and restart the program cycle without processing the rest of the commands and without printing the pattern space.

'[addr]X' '[addr]{ X ; X ; X }' '/regexp/X' '/regexp/{ X ; X ; X }' Addresses and regular expressions can be used as an 'if/then' conditional: If [ADDR] matches the current pattern space, execute the command(s). For example: The command '/^#/d' means: if the current pattern matches the regular expression '^#' (a line starting with a hash), then execute the 'd' command: delete the line without printing it, and restart the program cycle immediately.

'b' branch unconditionally (that is: always jump to a label, skipping or repeating other commands, without restarting a new cycle). Combined with an address, the branch can be conditionally executed on matched lines.

't' branch conditionally (that is: jump to a label) only if a 's///' command has succeeded since the last input line was read or another conditional branch was taken.

'T' similar but opposite to the 't' command: branch only if there has been no successful substitutions since the last input line was read.

The following two 'sed' programs are equivalent. The first (contrived) example uses the 'b' command to skip the 's///' command on lines containing '1'. The second example uses an address with negation ('!') to perform substitution only on desired lines. The 'y///' command is still executed on all lines:

 $ printf '%s\n' a1 a2 a3 | sed -E '/1/bx ; s/a/z/ ; :x ; y/123/456/'
 a4
 z5
 z6

 $ printf '%s\n' a1 a2 a3 | sed -E '/1/!s/a/z/ ; y/123/456/'
 a4
 z5
 z6

6.4.1 Branching and Cycles

The 'b','t' and 'T' commands can be followed by a label (typically a single letter). Labels are defined with a colon followed by one or more letters (e.g. ':x'). If the label is omitted the branch commands restart the cycle. Note the difference between branching to a label and restarting the cycle: when a cycle is restarted, 'sed' first prints the current content of the pattern space, then reads the next input line into the pattern space; Jumping to a label (even if it is at the beginning of the program) does not print the pattern space and does not read the next input line.

The following program is a no-op. The 'b' command (the only command in the program) does not have a label, and thus simply restarts the cycle. On each cycle, the pattern space is printed and the next input line is read:

 $ seq 3 | sed b
 1
 2
 3

The following example is an infinite-loop - it doesn't terminate and doesn't print anything. The 'b' command jumps to the 'x' label, and a new cycle is never started:

 $ seq 3 | sed ':x ; bx'

 # The above command requires gnu sed (which supports additional
 # commands following a label, without a newline). A portable equivalent:
 #     sed -e ':x' -e bx

Branching is often complemented with the 'n' or 'N' commands: both commands read the next input line into the pattern space without waiting for the cycle to restart. Before reading the next input line, 'n' prints the current pattern space then empties it, while 'N' appends a newline and the next input line to the pattern space.

Consider the following two examples:

 $ seq 3 | sed ':x ; n ; bx'
 1
 2
 3

 $ seq 3 | sed ':x ; N ; bx'
 1
 2
 3

Both examples do not inf-loop, despite never starting a new cycle.
In the first example, the 'n' commands first prints the content of the pattern space, empties the pattern space then reads the next input line.
In the second example, the 'N' commands appends the next input line to the pattern space (with a newline). Lines are accumulated in the pattern space until there are no more input lines to read, then the 'N' command terminates the 'sed' program. When the program terminates, the end-of-cycle actions are performed, and the entire pattern space is printed.
The second example requires GNU 'sed', because it uses the non-POSIX-standard behavior of 'N'. See the "'N' command on the last line" paragraph in *note Reporting Bugs::.
To further examine the difference between the two examples, try the following commands: printf '%s\n' aa bb cc dd | sed ':x ; n ; = ; bx' printf '%s\n' aa bb cc dd | sed ':x ; N ; = ; bx' printf '%s\n' aa bb cc dd | sed ':x ; n ; s/\n// ; bx' printf '%s\n' aa bb cc dd | sed ':x ; N ; s/\n// ; bx'

Fedora36 info sed

2.1 Overview

2.2 Command-Line Options

2.3 Exit status

3.1 'sed' script overview

3.2 'sed' commands summary

3.3 The 's' Command

3.4 Often-Used Commands

3.5 Less Frequently-Used Commands

3.6 Commands for 'sed' gurus

3.7 Commands Specific to GNU 'sed'

3.8 Multiple commands syntax

3.8.1 Commands Requiring a newline

4.1 Addresses overview

4.2 Selecting lines by numbers

4.3 selecting lines by text matching

4.4 Range Addresses

5.1 Overview of regular expression in 'sed'

5.2 Basic (BRE) and extended (ERE) regular expression

5.3 Overview of basic regular expression syntax

5.4 Overview of extended regular expression syntax

5.5 Character Classes and Bracket Expressions

5.6 regular expression extensions

5.7 Back-references and Subexpressions

5.8 Escape Sequences - specifying special characters

5.8.1 Escaping Precedence

5.9 Multibyte characters and Locale Considerations

5.9.1 Invalid multibyte characters

5.9.2 Upper/Lower case conversion

5.9.3 Multibyte regexp character classes

6.1 How 'sed' Works

6.2 Hold and Pattern Buffers

6.3 Multiline techniques - using D,G,H,N,P to process multiple lines

6.4 Branching and Flow Control

6.4.1 Branching and Cycles