本文已参与[新人创作礼]活动，一起开启掘金创作之路
前言：相较于透明度测试，透明度混合可以得到真正的半透明效果，他会使用 当前片元的透明度 作为混合因子与 颜色缓冲中的颜色 进行混合，得到新的颜色。但是需要 关闭深度写入！！！
Reason： 基于一个现实逻辑，对于透明的物体我们能够看到物体的内部，此时如果打开 深度写入 物体内部的“景象”会因为离相机远，深度测试不通过而被丢弃，就看不到了！（PS.物体内部的景象一定比看到的表面要离相机远=3=）

Shader "ShaderPath/BlendAlphaShader"//shader的选择路径
{
	Properties//该Shader可控的属性
	{
		_AlphaTex ("AlphaTex", 2D) = "white" {}//一张带有a通道值得图片
		_DiffuseColor ("DiffuseColor",Color) = (1,1,1,1)//漫反射的主色调
		_SpecularColor ("SpecularColor",Color) = (1,1,1,1)//高光反射的主色调
		_Gloss ("Gloss",Range(1,100)) = 2 //光泽度（反光度） 控制高光区域的大小
		_AlphaScale ("AlphaScale", Range(0,1)) = 0 //透明度变化范围
	}
	SubShader//子着色器
	{
		// ！！！！！特别注意 这里要关闭深度写入
		//Cull off 这里我们模拟的是物体整个是透明的 可以看到物体内部的样子 因此关闭剪裁 正反面都渲染
		Cull off ZWrite Off ZTest LEqual
		// IgnoreProject 中文翻译（忽略投影） 
		// 另外两个数值详看上一篇博客
		Tags{"Queue"="Transparent" "IgnoreProject"="True" "RenderType"="Transparent"}
		Pass
		{
			Tags{"LightMode" = "ForwardBase"}
			Blend SrcAlpha OneMinusSrcAlpha  // 透明度混合的重中之重！另外还有其他参数看文末
			//与ENDCG相照应，将CG代码包裹
			CGPROGRAM
			//顶点函数定义
			#pragma vertex diffusevert  
			//片元函数定义
			#pragma fragment diffusefrag
			//引入必要的Unity库 如下面的UnityObjectToClipPos 就是库中函数
			#include "UnityCG.cginc"
			//引入光照库 _LightColor0需要用
			#include "Lighting.cginc"
			struct appdata
			{
				float4 vertex : POSITION;//每个顶点结构体必须有的
				float3 normal : NORMAL;//定义法线
				float4 texcoord :TEXCOORD0; //第一组图片的纹理坐标信息
			};

			struct v2f
			{
				fixed3 worldNormal : TEXCOORD0; 
				float3 worldPos : TEXCOORD1;
				float2 uv :TEXCOORD2; //存放第一组纹理的UV信息
				float4 pos : SV_POSITION;//每个片元结构体必须有的
			};
			
			sampler2D _AlphaTex;
			float4 _AlphaTex_ST;
			fixed4 _DiffuseColor;
			fixed4 _SpecularColor;
			float _Gloss;
			float _AlphaScale;


			v2f diffusevert (appdata v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点从模型空间转换到剪裁空间
				o.worldNormal = normalize(UnityObjectToWorldNormal(v.normal));//把法线从模型空间转换到世界空间
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;//模型坐标转到世界坐标
				o.uv = TRANSFORM_TEX(v.texcoord,_AlphaTex); 
				return o;
			}
			
			fixed4 diffusefrag (v2f i) : SV_Target//返回一个RGBA到模型上
			{
				fixed4 texColor = tex2D(_AlphaTex,i.uv); //采集纹理  因为图片具有a通道 因此变量类型为fixed4
				fixed3 lightDir = UnityWorldSpaceLightDir(i.worldPos);//获取光源在世界空间下的方向（光源发射出来的方向）
				fixed3 diffuse = texColor * _LightColor0.rgb * _DiffuseColor * (1+dot(lightDir,i.worldNormal))/2;
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);//计算眼睛的方向 相机位置-模型的世界坐标 向量
				//Blinn-Phong模型高光 
				fixed3 halfView = normalize(lightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _SpecularColor * pow(saturate(dot(i.worldNormal,halfView)),_Gloss);
				return fixed4(diffuse +specular,_AlphaScale); //a通道返回原图片纹理的a通道值+_AlphaScale
			}
			ENDCG
		}
	}
	Fallback "Transparent/VertexLit"
}

当关闭深度写入的时候如下图 ZWrite Off ，当透明度为1即不透明的时候，会出现离相机近的表面不显示了反而显示出了对面的背面，这是因为我们使用了双面渲染，并且关闭了深度写入，导致同一个物体中，离相机远的片元先渲染，离相机近的因为关闭了深度写入误判为深度小于缓存中的深度而丢弃。在这里插入图片描述当打开深度写入的时候如下图 ZWrite On ，此时我们就无法观察到物体的内部情况，因为他们离相机远

关于Blend的一些参数

在这里插入图片描述请添加图片描述 在代码中使用的： Blend SrcAlpha OneMinusSrcAlpha 也就是 OutPutColor = srcColor *SrcAlpha + destColor×(1-SrcAlpha)

UnityShader透明度混合的应用

关于Blend的一些参数