UnityShader透明度测试的应用

本文已参与[新人创作礼]活动，一起开启掘金创作之路
文前简述：使用透明度测试所达到的透明效果很差，除非有特殊需求否则很少使用。 原理：给定一个透明度阈值x，超过x的片元直接舍弃，小于的就显示，所以会看到直接消失的情况。

Shader "ShaderPath/CutAlphaShader"//shader的选择路径
{
	Properties//该Shader可控的属性
	{
		_AlphaTex ("AlphaTex", 2D) = "white" {}//一张带有a通道值得图片
		_DiffuseColor ("DiffuseColor",Color) = (1,1,1,1)//漫反射的主色调
		_SpecularColor ("SpecularColor",Color) = (1,1,1,1)//高光反射的主色调
		_Gloss ("Gloss",Range(1,100)) = 2 //光泽度（反光度） 控制高光区域的大小
		_CutOut ("CutOut", Range(0,1)) = 0 //透明度阈值
	}
	SubShader//子着色器
	{
		// 以下均为默认值，详情可查看以往博客
		Cull Back ZWrite On ZTest LEqual
		// IgnoreProject 中文翻译（忽略投影） 
		// 另外两个数值详看下面的链接
		Tags{"Queue"="AlphaTest" "IgnoreProject"="True" "RenderType"="TransparentCutout"}
		Pass
		{
			Tags{"LightMode" = "ForwardBase"}
			//与ENDCG相照应，将CG代码包裹
			CGPROGRAM
			//顶点函数定义
			#pragma vertex diffusevert  
			//片元函数定义
			#pragma fragment diffusefrag
			//引入必要的Unity库 如下面的UnityObjectToClipPos 就是库中函数
			#include "UnityCG.cginc"
			//引入光照库 _LightColor0需要用
			#include "Lighting.cginc"
			struct appdata
			{
				float4 vertex : POSITION;//每个顶点结构体必须有的
				float3 normal : NORMAL;//定义法线
				float4 texcoord :TEXCOORD0; //第一组图片的纹理坐标信息
			};

			struct v2f
			{
				fixed3 worldNormal : TEXCOORD0; 
				float3 worldPos : TEXCOORD1;
				float2 uv :TEXCOORD2; //存放第一组纹理的UV信息
				float4 pos : SV_POSITION;//每个片元结构体必须有的
			};
			
			sampler2D _AlphaTex;
			float4 _AlphaTex_ST;
			fixed4 _DiffuseColor;
			fixed4 _SpecularColor;
			float _Gloss;
			float _CutOut;


			v2f diffusevert (appdata v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);//把顶点从模型空间转换到剪裁空间
				o.worldNormal = normalize(UnityObjectToWorldNormal(v.normal));//把法线从模型空间转换到世界空间
				o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;//模型坐标转到世界坐标
				o.uv = TRANSFORM_TEX(v.texcoord,_AlphaTex); 
				return o;
			}
			
			fixed4 diffusefrag (v2f i) : SV_Target//返回一个RGBA到模型上
			{
				fixed4 texColor = tex2D(_AlphaTex,i.uv); //采集纹理  因为图片具有a通道 因此变量类型为fixed4
				fixed3 lightDir = UnityWorldSpaceLightDir(i.worldPos);//获取光源在世界空间下的方向（光源发射出来的方向）
				fixed3 diffuse = texColor * _LightColor0.rgb * _DiffuseColor * (1+dot(lightDir,i.worldNormal))/2;
				clip(texColor.a - _CutOut); //透明度测试的关键代码，下面会有详解
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);//计算眼睛的方向 相机位置-模型的世界坐标 向量
				//Blinn-Phong模型高光 
				fixed3 halfView = normalize(lightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _SpecularColor * pow(saturate(dot(i.worldNormal,halfView)),_Gloss);
				return fixed4(diffuse +specular,1);
			}
			ENDCG
		}
	}
}

//关于
clip(texColor.a - _CutOut);
<=> //伪代码
if texColor.a - _CutOut >= 0 
	show;
else
	discard;

效果如图： 下图是纹理贴图，四个块的alpha值分别是0.8、0.7、0.6、0.5（左上→右下），因此看到最先消失的又是右下角

关于 Queue 和 RenderType 的说明详见 Queue和RenderType的理解