Created by Jerry Wang, last modified on May 05, 2014 Go to start of metadata
设计一个function module 模拟一个比较花费CPU计算时间的time consuming task.
FUNCTION zinsert.
*"----------------------------------------------------------------------
*"*"Local Interface:
*" IMPORTING
*" VALUE(IV_INDEX) TYPE COMM_PRODUCT-PRODUCT_ID
*"----------------------------------------------------------------------
DATA: ls_line TYPE zjerry1,
lv_cal TYPE timestamp,
lv_cal1 TYPE timestamp.
GET TIME STAMP FIELD lv_cal.
DO 10000 TIMES.
lv_cal = lv_cal + 1.
lv_cal = ( lv_cal * 13 ) / 12.
DO 100 TIMES.
GET TIME STAMP FIELD lv_cal1.
lv_cal = lv_cal * 13 / 17.
ENDDO.
ENDDO.
ls_line-code_value = iv_index.
INSERT zjerry1 FROM ls_line.
ASSERT sy-subrc = 0.
COMMIT WORK AND WAIT.
ENDFUNCTION.
在function 执行末尾会有一个database 的insert operation. Database table structure如下:
下面的report可以比较两种调用ZINSERT 方式的性能差异.
方法1是在循环里顺序调用ZINSERT，每次function call结束之后再进行下一次function调用。方法二是采用asynchronous RFC call的方式来并发操作.
两种方式的性能差异见如下图:
REPORT ztable.
PARAMETERS: num TYPE i OBLIGATORY DEFAULT 10.
DATA:ls_line TYPE zjerry1,
lv_start TYPE i,
lv_end TYPE i,
lv_taskid TYPE c LENGTH 8,
lv_index TYPE c LENGTH 4,
lv_finished TYPE i,
lv_count TYPE i.
START-OF-SELECTION.
PERFORM solution1.
PERFORM solution2.
FORM solution1.
DELETE FROM zjerry1.
GET RUN TIME FIELD lv_start.
DO num TIMES.
CALL FUNCTION 'ZINSERT'
EXPORTING
iv_index = CONV comm_product-product_id( sy-index ).
ENDDO.
GET RUN TIME FIELD lv_end.
lv_end = lv_end - lv_start.
WRITE: / 'solution1: ' , lv_end COLOR COL_NEGATIVE.
ENDFORM.
FORM solution2.
DELETE FROM zjerry1.
GET RUN TIME FIELD lv_start.
DO num TIMES.
lv_index = sy-index.
lv_taskid = 'Task' && lv_index.
CALL FUNCTION 'ZINSERT' STARTING NEW TASK lv_taskid PERFORMING callback ON END OF TASK
EXPORTING
iv_index = CONV comm_product-product_id( sy-index ).
ENDDO.
WAIT UNTIL lv_finished = num.
GET RUN TIME FIELD lv_end.
lv_end = lv_end - lv_start.
WRITE: / 'Solution2: ' , lv_end COLOR COL_NEGATIVE.
SELECT COUNT( * ) INTO lv_count FROM zjerry1.
ASSERT lv_count = num.
ENDFORM.
FORM callback USING p_task TYPE clike.
ADD 1 TO lv_finished.
ENDFORM.