安装规则

安装规则相当简单：对于MathFunctions，我们要安装库和头文件，对于应用程序，我们要安装可执行文件和配置的头文件。

因此，在 MathFunctions/CMakeLists.txt 的结尾处，我们添加了

install(TARGETS MathFunctions DESTINATION lib)
install(FILES MathFunctions.h DESTINATION include)

并在顶层CMakeLists.txt的末尾添加。

install(TARGETS Tutorial DESTINATION bin)
install(FILES "${PROJECT_BINARY_DIR}/TutorialConfig.h"
  DESTINATION include
  )

这就是创建本教程的基本本地安装所需要的全部内容。

运行 cmake 可执行文件或 cmake-gui 来配置项目，然后用你选择的构建工具来构建它。通过使用cmake命令的install选项（3.15中引入，旧版本的CMake必须使用make install）从命令行运行安装步骤，或者从IDE中构建INSTALL目标。这将安装适当的头文件、库和可执行文件。

CMake 变量 CMAKE_INSTALL_PREFIX 用于确定文件将被安装的根目录。如果使用 cmake --install 可以通过 --prefix 参数给出一个自定义的安装目录。对于多配置的工具，使用--config参数来指定配置。

验证安装后的教程是否可以运行。

测试支持

接下来让我们测试一下我们的应用程序。在顶层CMakeLists.txt文件的末尾，我们可以启用测试，然后添加一些基本测试来验证应用程序是否正常工作。

enable_testing()

# does the application run
add_test(NAME Runs COMMAND Tutorial 25)

# does the usage message work?
add_test(NAME Usage COMMAND Tutorial)
set_tests_properties(Usage
  PROPERTIES PASS_REGULAR_EXPRESSION "Usage:.*number"
  )

# define a function to simplify adding tests
function(do_test target arg result)
  add_test(NAME Comp${arg} COMMAND ${target} ${arg})
  set_tests_properties(Comp${arg}
    PROPERTIES PASS_REGULAR_EXPRESSION ${result}
    )
endfunction(do_test)

# do a bunch of result based tests
do_test(Tutorial 4 "4 is 2")
do_test(Tutorial 9 "9 is 3")
do_test(Tutorial 5 "5 is 2.236")
do_test(Tutorial 7 "7 is 2.645")
do_test(Tutorial 25 "25 is 5")
do_test(Tutorial -25 "-25 is [-nan|nan|0]")
do_test(Tutorial 0.0001 "0.0001 is 0.01")

第一个测试只是简单地验证应用程序是否运行，没有segfault或其他崩溃，并且返回值为零。这是CTest测试的基本形式。

下一个测试利用PASS_REGULAR_EXPRESSION测试属性来验证测试的输出是否包含某些字符串。在这种情况下，验证当提供的参数数量不正确时，是否会打印出使用信息。

最后，我们有一个名为do_test的函数，它运行应用程序并验证给定输入的计算平方根是否正确。每调用一次do_test，就会在项目中添加一个测试，包括名称、输入和基于传递的参数的预期结果。

重建应用程序，然后cd到二进制目录，运行ctest可执行文件：ctest -N和ctest -VV。对于多配置生成器（如Visual Studio），必须指定配置类型。例如，要在Debug模式下运行测试，从构建目录中使用ctest -C Debug -VV（不是Debug子目录！）。或者，从 IDE 中构建 RUN_TESTS 目标。

[CMake翻译]安装和测试（步骤4）

安装规则

测试支持