30天自制操作系统
转载CSDN：blog.csdn.net/zl182062088…
第3天进入32位模式并导入 C 语言
32位模式前期准备
harib00h
准备材料（windows环境）
- VMware Workstation
- Visual Studio Code
- 程序和源代码：pan.baidu.com/s/1bFGAYgnA… 提取码：d210
- Makefile
- windows 批处理
开始实验
-
在tolset文件夹下创建子文件侠harib00h;
-
打开记事本，输入以下代码并另存为 !cons_nt.bat文件（windows 批处理），存放在harib00h文件夹中;
cmd.exe
ps:当然也可以直接使用 win + r 快捷键也可以，不过最好还是创建一个比较好。因为以后打开时不需要再麻烦了。 3. 打vc code，输入以下代码并保存为 haribote.nas,存放在harib00h文件夹中。
; haribote-os
; TAB = 4
; 有关BOOT_INFO
CYLS EQU 0x0ff0 ; 设定启动区
LEDS EQU 0x0ff1
VMODE EQU 0x0ff2 ; 关于颜色数目的信息，颜色的位数
SCRNX EQU 0x0ff4 ; 分辨率的X（screen x）
SCRMY EQU 0x0ff6 ; 分辨率的Y（screen y)
VRAM EQU 0x0ff8 ; 图像缓冲区的开始地址
ORG 0xc200 ; 这个程序要被装载到内存的什么地方呢？
MOV AL,0x13 ; VGA显卡，320x200x8位彩色
MOV AH,0X00
INT 0X10
MOV BYTE [VMODE],8 ; 记录画面模式
MOV WORD [SCRNX],320
MOV WORD [SCRMY],200
MOV DWORD [VRAM],0x00a0000
; 用BIOS取得键盘各种LED指示灯的状态
MOV AH,0x02
INT 0x16 ; keyboard BIOS
MOV [LEDS],AL
fin:
HLT
JMP fin
- 打开 VC code 创建 ipl10.nas 文件，输入以下代码，也存放的harib00h中；
; haribote-ipl
; TAB=4
CYLS EQU 10 ; 要读取到什么程度
ORG 0x7c00 ; 启动装载程序
; 以下记述用于标准FAT12格式软盘
JMP entry
DB 0x90
DB "HARIBOTE" ; 磁盘名称（可以是任意字符串）
DW 512 ; 每个扇区的大小（必须是512）
DB 1 ; 簇的大小（必须为一个扇区）
DW 1 ; FAT12的起始位置（一般从第一个扇区开始
DB 2 ; FAT的个数（必须为2）
DW 224 ; 根目录的大小（一般设成224项）
DW 2880 ; 该磁盘的大小（必须是2880扇区）
DB 0xf0 ; 该磁盘的种类（必须是0xf0
DW 9 ; FAt的长度（必须是9扇区）
DW 18 ; 一个磁道有几个扇区（必须是18）
DW 2 ; 磁头数（必须是2）
DD 0 ; 不使用分区，必须是0
DD 2880 ; 磁盘大小
DB 0,0,0x29 ; 意义不明固定
DD 0xffffffff ; （可能是）卷标号码
DB "HARIBOTEOS " ; 磁盘的名称（11字节）
DB "FAT12 " ; 磁盘格式名称（8字节）
RESB 18 ; 先空出18字节
; 程序主体
entry:
MOV AX,0 ; 初始化寄存器
MOV SS,AX
MOV SP,0x7c00
MOV DS,AX
; 读磁盘
MOV AX,0x0820
MOV ES,AX
MOV CH,0 ; 柱面 0
MOV DH,0 ; 磁头 0
MOV CL,2 ; 扇区 2
readloop:
MOV SI,0 ; 记录失败次数的寄存器
retry:
MOV AH,0x02 ; AH=0x02 : 读入磁盘
MOV AL,1 ; 1 个扇区
MOV BX,0
MOV DL,0x00 ; A 驱动器
INT 0x13 ; 调用磁盘BIOS
JNC next ; 没出错时跳转到next
ADD SI,1 ; SI 加 1
CMP SI,5 ; 比较 SI 与 5
JAE error ; SI >= 5 时，跳转到error
MOV AH,0x00
MOV DL,0x00 ; A 驱动器
INT 0x13 ; 重置驱动器
JMP retry
next:
MOV AX,ES ; 把内存地址后移0x200
ADD AX,0x0020
MOV ES,AX ; 因为没有 ADD ES,0x020 指令，所以这里稍微绕个弯
ADD CL,1 ; CL 加 1
CMP CL,18 ; 比较 CL 与 18
JBE readloop ; 如果 CL <= 18，则跳转至readloop
MOV CL,1
ADD DH,1
CMP DH,2
JB readloop ; 如果 DH < 2， 则跳转到readloop
MOV DH,0
ADD CH,1
CMP CH,CYLS
JB readloop ; 如果 CH < CYLS，则跳转至readloop
; 因为看完了实行haribote.sys
MOV [0x0ff0],CH ; IPL读到什么地方结束
JMP 0xc200
error:
MOV SI,msg
putloop:
MOV AL,[SI]
ADD SI,1 ; SI 加 1
CMP AL,0
JE fin
MOV AH,0x0e ; 显示一个文字
MOV BX,15 ; 指定字符颜色
INT 0x10 ; 调用显卡BIOS
JMP putloop
fin:
HLT ; 让CPu停止，等待指令
JMP fin ; 无限循环
msg:
DB 0x0a, 0x0a ; 换行两次
DB "load error"
DB 0x0a ; 换行
DB 0
RESB 0x7dfe-$ ; 重复0x00一直到0x7dfe
DB 0x55, 0xaa
- 打开记事本，输入以下代码，另存为 make.bat, 同样放到harib00h中；
..\z_tools\make.exe %1 %2 %3 %4 %5 %6 %7 %8 %9
- 创建 Makefile,并输入以下代码并存放到harib00h中;
TOOLPATH = ../z_tools/
MAKE = $(TOOLPATH)make.exe -r
NASK = $(TOOLPATH)nask.exe
EDIMG = $(TOOLPATH)edimg.exe
IMGTOL = $(TOOLPATH)imgtol.com
COPY = copy
DEL = del
# 默认
default :
$(MAKE) img
# 文件生成规则
ipl10.bin : ipl10.nas Makefile
$(NASK) ipl10.nas ipl10.bin ipl10.lst
haribote.sys : haribote.nas Makefile
$(NASK) haribote.nas haribote.sys haribote.lst
haribote.img : ipl10.bin haribote.sys Makefile
$(EDIMG) imgin:../z_tools/fdimg0at.tek \
wbinimg src:ipl10.bin len:512 from:0 to:0 \
copy from:haribote.sys to:@: \
imgout:haribote.img
# 命令
img :
$(MAKE) haribote.img
run :
$(MAKE) img
$(COPY) haribote.img ..\z_tools\qemu\fdimage0.bin
$(MAKE) -C ../z_tools/qemu
install :
$(MAKE) img
$(IMGTOL) w a: haribote.img
clean :
-$(DEL) ipl10.bin
-$(DEL) ipl10.lst
-$(DEL) haribote.sys
-$(DEL) haribote.lst
src_only :
$(MAKE) clean
-$(DEL) haribote.img
编译及运行
- 双击 !cons_nt.bat,并在打开的命令行中输入 make run
- VMware中运行结果，如下图
