还在买向日葵开机棒？不如自己做一个小爱同学开机棒！

本文已参与「新人创作礼」活动，一起开启掘金创作之路。

实现原理

硬件： WIFI模块（esp01s）、esp01s继电器、杜邦线若干、支持外接开机键的电脑、一拖二开机线
软件： Arduino、点灯科技平台、米家APP
Arduino代码：

#define BLINKER_WIFI
#define BLINKER_MIOT_OUTLET   //小爱同学

#include <Blinker.h>

char auth[] = "*******";  //设备key
char ssid[] = "*******";  //路由器wifi ssid
char pswd[] = "*******";  //路由器wifi 密码
BlinkerButton Button1("btn-aaa");     //定义按钮键名
bool oState = false;
int counter = 0;
void miotPowerState(const String & state)
{
    BLINKER_LOG("need set power state: ", state);

    if (state == BLINKER_CMD_ON) {     //小爱同学控制开命令 此处修改为点动模式，适合按钮操作，
        digitalWrite(0, LOW);
        delay(200);
        digitalWrite(0, HIGH);
        BlinkerMIOT.powerState("on");

        BlinkerMIOT.print();

        oState = true;
    }
    else if (state == BLINKER_CMD_OFF) {   //小爱同学控制关命令 此处修改为点动模式，适合按钮操作，
        digitalWrite(0,LOW);
        delay(200);
        digitalWrite(0, HIGH);
        BlinkerMIOT.powerState("off");

        BlinkerMIOT.print();

        oState = false;
    }
}

void miotQuery(int32_t queryCode)      //小爱同学控制
{
    BLINKER_LOG("MIOT Query codes: ", queryCode);

    switch (queryCode)
    {
        case BLINKER_CMD_QUERY_ALL_NUMBER :
            BLINKER_LOG("MIOT Query All");
            BlinkerMIOT.powerState(oState ? "on" : "off");
            BlinkerMIOT.print();
            break;
        case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
            BLINKER_LOG("MIOT Query Power State");
            BlinkerMIOT.powerState(oState ? "on" : "off");
            BlinkerMIOT.print();
            break;
        default :
            BlinkerMIOT.powerState(oState ? "on" : "off");
            BlinkerMIOT.print();
            break;
    }
}

void dataRead(const String & data)      // 如果未绑定的组件被触发，则会执行其中内容
{
    BLINKER_LOG("Blinker readString: ", data);

    Blinker.vibrate();
   
    uint32_t BlinkerTime = millis();
   
    Blinker.print("millis", BlinkerTime);
}

void button1_callback(const String & state)     //点灯app内控制按键触发
{
    BLINKER_LOG("get button state: ", state);
    digitalWrite(0,LOW);
    delay(200);
    digitalWrite(0, HIGH);
}

void setup()
{
    Serial.begin(115200);
    BLINKER_DEBUG.stream(Serial);

    pinMode(0, OUTPUT);              //定义io口为输出
    digitalWrite(0, HIGH);           //定义io默认为高电平

    Blinker.begin(auth, ssid, pswd);
    Blinker.attachData(dataRead);
   
    BlinkerMIOT.attachPowerState(miotPowerState);
    BlinkerMIOT.attachQuery(miotQuery);
    Button1.attach(button1_callback);      
}

void loop()
{
    Blinker.run();
}

线路连接思路：
思路一（主板支持关机USB带电）：
（1）连接线路时请先断电。
（2）继电器的5v输入随意接到主板USB插座的vcc接口上，继电器的gnd接口连接USB的gnd接口。下面的图片是电脑主板USB插座的图解。
输入图片说明
（3）esp01s芯片插到esp01s继电器上以后，直接由继电器供电。
（4）一拖二开机线母头连接电脑主板上的pw+和pw-针脚，不用区分正负极。
（5）一拖二开机线一头连接机箱的开机键，保证我们能正常使用机箱上开机键，另一头连接esp01s继电器的常闭接口（no）和公共接口（com）。这一步同样不需要区分正负极，继电器模拟的是人手按开机键的操作。开机键开机的原理是pw+和pw-针脚短接形成一个不超过3秒的电流，让主板启动，不管接口如何连接，电流都是从pw+流向排为-，不会因为杜邦线接反了而导致无法开机。

思路二（主板不支持关机USB带电）：（1）步骤与思路一大体相同，唯一不同的地方是第二步继电器如何在主板中取到一个5v的电。由于主板不支持USB关机供电，我们就要从其他地方找一个5v的电压，我们可以直接从主板主电源线的5VSB针脚中取到。下面是20pin和24pin针脚的定义。
输入图片说明

注意：这个方法太过暴力，需要把主板电源线剪断加上一根线连接继电器，有一定的风险，别轻易尝试！！！

程序配置思路：
（1）配置开发环境，安装arduino（可以参考我这篇博客）。
（2）安装点灯库，并申请一个设备key（可以参考我开发小爱同学温湿度传感器的博客）
（3）修改ino文件，修改成你的WIFI账户和密码，并添加key
（4）烧录程序
（5）在米家APP中绑定点灯平台，并为设备设置别名。
（6）跟小爱同学说：“小爱同学，打开电脑”
（7）跟小爱同学说：“小爱同学，关闭电脑”
（8）愉快的使用吧